publish: the public projection begins here
This is a projection, not a development branch. The tree above was constructed from the internal source named below under a manifest that decides which paths may leave, then scanned as a whole tree rather than as a series of patches, and only then published. Public history starts here because the history before it was not admissible, and neither was the tree. What used to stand in this repository included a rescue copy of another machine, a directory of phone handoffs, deployment wired to one house, and a submodule pointing at a forge no stranger can reach. None of that was ever the product. It stays in the private forge, which is allowed to hold the whole working organism, and this is what was deliberately sent out instead. Three mechanisms produced this tree, in decreasing order of trust. A top-level path the manifest does not name never arrives at all, which is the one that catches directories nobody has thought of yet. Named internal files inside admitted roots are dropped. A short, reviewed table replaces deployment defaults that a public build must not carry -- an endpoint aimed at one LAN, a VPN profile belonging to one phone, packaging built from one checkout path. Everything after this commit is an ordinary publication with the same three trailers, so a force push stops being routine and starts meaning that something deliberate happened. The trailers bind the projection to its source without pretending the public SHA is the private one: same lineage, different tree, and the record says so. Source-Sha: 8f27b1e76a8fef560a336aba18e6990713ff1047 Policy-Sha: 6b261d2f3e6e1fb19874846ba4bb1dfe15565d25b8618c1c1afba0419c101d27 Tree-Digest: 18ec3563c5e5ef9a414993a9f6734b251ff9ed3cd56eebdd6cac01e45c6e3067
This commit is contained in:
Fimeg
commit
8f42fc953d
1476 changed files with 238455 additions and 0 deletions
198
surfaces/quickshell/ii-base/killDialog.qml
Normal file
198
surfaces/quickshell/ii-base/killDialog.qml
Normal file
|
|
@ -0,0 +1,198 @@
|
|||
//@ pragma UseQApplication
|
||||
//@ pragma Env QS_NO_RELOAD_POPUP=1
|
||||
//@ pragma Env QT_QUICK_CONTROLS_STYLE=Basic
|
||||
//@ pragma Env QT_QUICK_FLICKABLE_WHEEL_DECELERATION=10000
|
||||
|
||||
// Adjust this to make the app smaller or larger
|
||||
//@ pragma Env QT_SCALE_FACTOR=1
|
||||
|
||||
import QtQuick
|
||||
import QtQuick.Controls
|
||||
import QtQuick.Layouts
|
||||
import QtQuick.Window
|
||||
import Quickshell
|
||||
import Quickshell.Io
|
||||
import Quickshell.Hyprland
|
||||
import qs.services
|
||||
import qs.modules.common
|
||||
import qs.modules.common.widgets
|
||||
import qs.modules.common.functions
|
||||
|
||||
ApplicationWindow {
|
||||
id: root
|
||||
property int conflictCount: 0
|
||||
onConflictCountChanged: {
|
||||
if (conflictCount === 0) {
|
||||
root.close();
|
||||
}
|
||||
}
|
||||
|
||||
property real contentPadding: 8
|
||||
visible: true
|
||||
onClosing: {
|
||||
Qt.quit()
|
||||
}
|
||||
title: Translation.tr("Shell conflicts killer")
|
||||
|
||||
Component.onCompleted: {
|
||||
Config.readWriteDelay = 0;
|
||||
Config.blockWrites = true;
|
||||
MaterialThemeLoader.reapplyTheme();
|
||||
}
|
||||
|
||||
minimumWidth: 400
|
||||
minimumHeight: 300
|
||||
maximumWidth: 400
|
||||
maximumHeight: 300
|
||||
width: 400
|
||||
height: 300
|
||||
color: Appearance.m3colors.m3background
|
||||
|
||||
component ConflictingProgramGroup: ColumnLayout {
|
||||
id: conflictGroup
|
||||
required property list<string> programs
|
||||
required property string description
|
||||
visible: false
|
||||
onVisibleChanged: {
|
||||
conflictCount += visible ? 1 : -1
|
||||
}
|
||||
|
||||
signal alwaysSelected()
|
||||
|
||||
Process {
|
||||
running: true
|
||||
command: ["pidof", ...conflictGroup.programs]
|
||||
onExited: (exitCode, exitStatus) => {
|
||||
if (exitCode === 0) {
|
||||
conflictGroup.visible = true
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
StyledText {
|
||||
text: conflictGroup.programs.join(", ")
|
||||
font.pixelSize: Appearance.font.pixelSize.normal
|
||||
}
|
||||
StyledText {
|
||||
font {
|
||||
pixelSize: Appearance.font.pixelSize.smaller
|
||||
italic: true
|
||||
}
|
||||
text: conflictGroup.description
|
||||
color: Appearance.colors.colSubtext
|
||||
}
|
||||
RowLayout {
|
||||
Layout.alignment: Qt.AlignRight
|
||||
|
||||
RippleButton {
|
||||
colBackground: Appearance.colors.colLayer2
|
||||
contentItem: StyledText {
|
||||
text: Translation.tr("Always")
|
||||
}
|
||||
onClicked: {
|
||||
Quickshell.execDetached(["killall", ...conflictGroup.programs])
|
||||
conflictGroup.alwaysSelected()
|
||||
conflictGroup.visible = false
|
||||
}
|
||||
}
|
||||
RippleButton {
|
||||
colBackground: Appearance.colors.colLayer2
|
||||
contentItem: StyledText {
|
||||
text: Translation.tr("Yes")
|
||||
}
|
||||
onClicked: {
|
||||
Quickshell.execDetached(["killall", ...conflictGroup.programs])
|
||||
conflictGroup.visible = false
|
||||
}
|
||||
}
|
||||
RippleButton {
|
||||
colBackground: Appearance.colors.colLayer2
|
||||
contentItem: StyledText {
|
||||
text: Translation.tr("No")
|
||||
}
|
||||
onClicked: conflictGroup.visible = false
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
ColumnLayout {
|
||||
anchors {
|
||||
fill: parent
|
||||
margins: contentPadding
|
||||
}
|
||||
|
||||
Item {
|
||||
// Titlebar
|
||||
visible: Config.options?.windows.showTitlebar
|
||||
Layout.fillWidth: true
|
||||
implicitHeight: Math.max(welcomeText.implicitHeight, windowControlsRow.implicitHeight)
|
||||
StyledText {
|
||||
id: welcomeText
|
||||
anchors {
|
||||
left: Config.options.windows.centerTitle ? undefined : parent.left
|
||||
horizontalCenter: Config.options.windows.centerTitle ? parent.horizontalCenter : undefined
|
||||
verticalCenter: parent.verticalCenter
|
||||
leftMargin: 12
|
||||
}
|
||||
color: Appearance.colors.colOnLayer0
|
||||
text: Translation.tr("Kill conflicting programs?")
|
||||
font {
|
||||
family: Appearance.font.family.title
|
||||
pixelSize: Appearance.font.pixelSize.title
|
||||
variableAxes: Appearance.font.variableAxes.title
|
||||
}
|
||||
}
|
||||
RowLayout { // Window controls row
|
||||
id: windowControlsRow
|
||||
anchors.verticalCenter: parent.verticalCenter
|
||||
anchors.right: parent.right
|
||||
RippleButton {
|
||||
buttonRadius: Appearance.rounding.full
|
||||
implicitWidth: 35
|
||||
implicitHeight: 35
|
||||
onClicked: root.close()
|
||||
contentItem: MaterialSymbol {
|
||||
anchors.centerIn: parent
|
||||
horizontalAlignment: Text.AlignHCenter
|
||||
text: "close"
|
||||
iconSize: 20
|
||||
}
|
||||
}
|
||||
}
|
||||
}
|
||||
Rectangle {
|
||||
// Content container
|
||||
color: Appearance.m3colors.m3surfaceContainerLow
|
||||
radius: Appearance.rounding.windowRounding - root.contentPadding
|
||||
implicitHeight: contentColumn.implicitHeight
|
||||
implicitWidth: contentColumn.implicitWidth
|
||||
Layout.fillWidth: true
|
||||
Layout.fillHeight: true
|
||||
|
||||
ColumnLayout {
|
||||
id: contentColumn
|
||||
anchors.fill: parent
|
||||
spacing: 12
|
||||
|
||||
ConflictingProgramGroup {
|
||||
id: kded6Group
|
||||
Layout.alignment: Qt.AlignHCenter
|
||||
Layout.fillHeight: false
|
||||
programs: ["kded6"]
|
||||
description: Translation.tr("Conflicts with the shell's system tray implementation")
|
||||
onAlwaysSelected: Config.options.conflictKiller.autoKillTrays = true
|
||||
}
|
||||
|
||||
ConflictingProgramGroup {
|
||||
id: notificationDaemons
|
||||
Layout.alignment: Qt.AlignHCenter
|
||||
Layout.fillHeight: false
|
||||
programs: ["mako", "dunst"]
|
||||
description: Translation.tr("Conflicts with the shell's notification implementation")
|
||||
onAlwaysSelected: Config.options.conflictKiller.autoKillNotificationDaemons = true
|
||||
}
|
||||
|
||||
}
|
||||
}
|
||||
}
|
||||
}
|
||||
Loading…
Reference in a new issue