publish: the public projection begins here
This is a projection, not a development branch. The tree above was constructed from the internal source named below under a manifest that decides which paths may leave, then scanned as a whole tree rather than as a series of patches, and only then published. Public history starts here because the history before it was not admissible, and neither was the tree. What used to stand in this repository included a rescue copy of another machine, a directory of phone handoffs, deployment wired to one house, and a submodule pointing at a forge no stranger can reach. None of that was ever the product. It stays in the private forge, which is allowed to hold the whole working organism, and this is what was deliberately sent out instead. Three mechanisms produced this tree, in decreasing order of trust. A top-level path the manifest does not name never arrives at all, which is the one that catches directories nobody has thought of yet. Named internal files inside admitted roots are dropped. A short, reviewed table replaces deployment defaults that a public build must not carry -- an endpoint aimed at one LAN, a VPN profile belonging to one phone, packaging built from one checkout path. Everything after this commit is an ordinary publication with the same three trailers, so a force push stops being routine and starts meaning that something deliberate happened. The trailers bind the projection to its source without pretending the public SHA is the private one: same lineage, different tree, and the record says so. Source-Sha: 8f27b1e76a8fef560a336aba18e6990713ff1047 Policy-Sha: 6b261d2f3e6e1fb19874846ba4bb1dfe15565d25b8618c1c1afba0419c101d27 Tree-Digest: 18ec3563c5e5ef9a414993a9f6734b251ff9ed3cd56eebdd6cac01e45c6e3067
This commit is contained in:
Fimeg
commit
8f42fc953d
1476 changed files with 238455 additions and 0 deletions
445
surfaces/quickshell/ii-base/services/LauncherSearch.qml
Normal file
445
surfaces/quickshell/ii-base/services/LauncherSearch.qml
Normal file
|
|
@ -0,0 +1,445 @@
|
|||
pragma Singleton
|
||||
|
||||
import qs.modules.common
|
||||
import qs.modules.common.models
|
||||
import qs.modules.common.functions
|
||||
import QtQuick
|
||||
import Qt.labs.folderlistmodel
|
||||
import Quickshell
|
||||
import Quickshell.Io
|
||||
import Quickshell.Hyprland
|
||||
|
||||
Singleton {
|
||||
id: root
|
||||
|
||||
property string query: ""
|
||||
|
||||
function ensurePrefix(prefix) {
|
||||
if ([Config.options.search.prefix.action, Config.options.search.prefix.app, Config.options.search.prefix.clipboard, Config.options.search.prefix.emojis, Config.options.search.prefix.math, Config.options.search.prefix.shellCommand, Config.options.search.prefix.webSearch,].some(i => root.query.startsWith(i))) {
|
||||
root.query = prefix + root.query.slice(1);
|
||||
} else {
|
||||
root.query = prefix + root.query;
|
||||
}
|
||||
}
|
||||
onQueryChanged: {
|
||||
FileSearch.search(StringUtils.cleanPrefix(root.query, Config.options.search.prefix.app));
|
||||
}
|
||||
|
||||
// https://specifications.freedesktop.org/menu/latest/category-registry.html
|
||||
property list<string> mainRegisteredCategories: ["AudioVideo", "Development", "Education", "Game", "Graphics", "Network", "Office", "Science", "Settings", "System", "Utility"]
|
||||
property list<string> appCategories: DesktopEntries.applications.values.reduce((acc, entry) => {
|
||||
for (const category of entry.categories) {
|
||||
if (!acc.includes(category) && mainRegisteredCategories.includes(category)) {
|
||||
acc.push(category);
|
||||
}
|
||||
}
|
||||
return acc;
|
||||
}, []).sort()
|
||||
|
||||
// Load user action scripts from ~/.config/illogical-impulse/actions/
|
||||
// Uses FolderListModel to auto-reload when scripts are added/removed
|
||||
property var userActionScripts: {
|
||||
const actions = [];
|
||||
for (let i = 0; i < userActionsFolder.count; i++) {
|
||||
const fileName = userActionsFolder.get(i, "fileName");
|
||||
const filePath = userActionsFolder.get(i, "filePath");
|
||||
if (fileName && filePath) {
|
||||
const actionName = fileName.replace(/\.[^/.]+$/, ""); // strip extension
|
||||
actions.push({
|
||||
action: actionName,
|
||||
execute: ((path) => (args) => {
|
||||
Quickshell.execDetached([path, ...(args ? args.split(" ") : [])]);
|
||||
})(FileUtils.trimFileProtocol(filePath.toString()))
|
||||
});
|
||||
}
|
||||
}
|
||||
return actions;
|
||||
}
|
||||
|
||||
FolderListModel {
|
||||
id: userActionsFolder
|
||||
folder: Qt.resolvedUrl(Directories.userActions)
|
||||
showDirs: false
|
||||
showHidden: false
|
||||
sortField: FolderListModel.Name
|
||||
}
|
||||
|
||||
property var searchActions: [
|
||||
{
|
||||
action: "accentcolor",
|
||||
execute: args => {
|
||||
Quickshell.execDetached([Directories.wallpaperSwitchScriptPath, "--noswitch", "--color", ...(args != '' ? [`${args}`] : [])]);
|
||||
}
|
||||
},
|
||||
{
|
||||
action: "dark",
|
||||
execute: () => {
|
||||
Quickshell.execDetached([Directories.wallpaperSwitchScriptPath, "--mode", "dark", "--noswitch"]);
|
||||
}
|
||||
},
|
||||
{
|
||||
action: "konachanwallpaper",
|
||||
execute: () => {
|
||||
Quickshell.execDetached([Quickshell.shellPath("scripts/colors/random/random_konachan_wall.sh")]);
|
||||
}
|
||||
},
|
||||
{
|
||||
action: "light",
|
||||
execute: () => {
|
||||
Quickshell.execDetached([Directories.wallpaperSwitchScriptPath, "--mode", "light", "--noswitch"]);
|
||||
}
|
||||
},
|
||||
{
|
||||
action: "superpaste",
|
||||
execute: args => {
|
||||
if (!/^(\d+)/.test(args.trim())) {
|
||||
// Invalid if doesn't start with numbers
|
||||
Quickshell.execDetached(["notify-send", Translation.tr("Superpaste"), Translation.tr("Usage: <tt>%1superpaste NUM_OF_ENTRIES[i]</tt>\nSupply <tt>i</tt> when you want images\nExamples:\n<tt>%1superpaste 4i</tt> for the last 4 images\n<tt>%1superpaste 7</tt> for the last 7 entries").arg(Config.options.search.prefix.action), "-a", "Shell"]);
|
||||
return;
|
||||
}
|
||||
const syntaxMatch = /^(?:(\d+)(i)?)/.exec(args.trim());
|
||||
const count = syntaxMatch[1] ? parseInt(syntaxMatch[1]) : 1;
|
||||
const isImage = !!syntaxMatch[2];
|
||||
Cliphist.superpaste(count, isImage);
|
||||
}
|
||||
},
|
||||
{
|
||||
action: "todo",
|
||||
execute: args => {
|
||||
Todo.addTask(args);
|
||||
}
|
||||
},
|
||||
{
|
||||
action: "wallpaper",
|
||||
execute: () => {
|
||||
Hyprland.dispatch(`hl.dsp.global("quickshell:wallpaperSelectorToggle")`)
|
||||
}
|
||||
},
|
||||
{
|
||||
action: "wipeclipboard",
|
||||
execute: () => {
|
||||
Cliphist.wipe();
|
||||
}
|
||||
},
|
||||
]
|
||||
|
||||
// Combined built-in and user actions
|
||||
property var allActions: searchActions.concat(userActionScripts)
|
||||
|
||||
property string mathResult: ""
|
||||
property bool clipboardWorkSafetyActive: {
|
||||
const enabled = Config.options.workSafety.enable.clipboard;
|
||||
const sensitiveNetwork = (StringUtils.stringListContainsSubstring(Network.networkName.toLowerCase(), Config.options.workSafety.triggerCondition.networkNameKeywords));
|
||||
return enabled && sensitiveNetwork;
|
||||
}
|
||||
|
||||
function containsUnsafeLink(entry) {
|
||||
if (entry == undefined)
|
||||
return false;
|
||||
const unsafeKeywords = Config.options.workSafety.triggerCondition.linkKeywords;
|
||||
return StringUtils.stringListContainsSubstring(entry.toLowerCase(), unsafeKeywords);
|
||||
}
|
||||
|
||||
Timer {
|
||||
id: nonAppResultsTimer
|
||||
interval: Config.options.search.nonAppResultDelay
|
||||
onTriggered: {
|
||||
let expr = root.query;
|
||||
if (expr.startsWith(Config.options.search.prefix.math)) {
|
||||
expr = expr.slice(Config.options.search.prefix.math.length);
|
||||
}
|
||||
mathProc.calculateExpression(expr);
|
||||
}
|
||||
}
|
||||
|
||||
Process {
|
||||
id: mathProc
|
||||
property list<string> baseCommand: ["qalc", "-t"]
|
||||
function calculateExpression(expression) {
|
||||
mathProc.running = false;
|
||||
mathProc.command = baseCommand.concat(expression);
|
||||
mathProc.running = true;
|
||||
}
|
||||
stdout: SplitParser {
|
||||
onRead: data => {
|
||||
root.mathResult = data;
|
||||
}
|
||||
}
|
||||
}
|
||||
property list<var> fileResults: {
|
||||
if (!Config.options.search.fileSearch.enable) return [];
|
||||
if (!FileSearch.results || FileSearch.results.length === 0) return [];
|
||||
|
||||
return FileSearch.results.map(path => {
|
||||
const trimmed = FileUtils.trimFileProtocol(path.path);
|
||||
const isDir = path.isDir;
|
||||
const displayName = isDir ? FileUtils.folderNameForPath(trimmed) : FileUtils.fileNameForPath(trimmed);
|
||||
const parentDir = FileUtils.parentDirectory(trimmed);
|
||||
return resultComp.createObject(null, {
|
||||
rawValue: trimmed,
|
||||
name: displayName || trimmed,
|
||||
verb: Translation.tr("Open"),
|
||||
type: isDir ? Translation.tr("Folder") : Translation.tr("File"),
|
||||
iconName: isDir ? "folder" : "description",
|
||||
iconType: LauncherSearchResult.IconType.Material,
|
||||
execute: () => {
|
||||
Qt.openUrlExternally(`file://${trimmed}`);
|
||||
},
|
||||
actions: [resultComp.createObject(null, {
|
||||
name: Translation.tr("Open Parent folder"),
|
||||
iconName: "folder_open",
|
||||
iconType: LauncherSearchResult.IconType.Material,
|
||||
execute: () => {
|
||||
if (parentDir) {
|
||||
Qt.openUrlExternally(`file://${parentDir}`);
|
||||
}
|
||||
}
|
||||
})]
|
||||
});
|
||||
});
|
||||
}
|
||||
|
||||
property list<var> results: {
|
||||
// Search results are handled here
|
||||
////////////////// Skip? //////////////////
|
||||
if (root.query == "")
|
||||
return [];
|
||||
|
||||
///////////// Special cases ///////////////
|
||||
if (root.query.startsWith(Config.options.search.prefix.clipboard)) {
|
||||
// Clipboard
|
||||
const searchString = StringUtils.cleanPrefix(root.query, Config.options.search.prefix.clipboard);
|
||||
const allClipStrings = [searchString, ...KeymapTranslation.translateAll(searchString)];
|
||||
const seenClipEntries = new Set();
|
||||
const clipEntries = allClipStrings.reduce((acc, q) => {
|
||||
return acc.concat(Cliphist.fuzzyQuery(q).filter(e => {
|
||||
if (seenClipEntries.has(e)) return false;
|
||||
seenClipEntries.add(e);
|
||||
return true;
|
||||
}));
|
||||
}, []);
|
||||
return clipEntries.map((entry, index, array) => {
|
||||
const mightBlurImage = Cliphist.entryIsImage(entry) && root.clipboardWorkSafetyActive;
|
||||
let shouldBlurImage = mightBlurImage;
|
||||
if (mightBlurImage) {
|
||||
shouldBlurImage = shouldBlurImage && (root.containsUnsafeLink(array[index - 1]) || root.containsUnsafeLink(array[index + 1]));
|
||||
}
|
||||
const type = `#${entry.match(/^\s*(\S+)/)?.[1] || ""}`;
|
||||
return resultComp.createObject(null, {
|
||||
rawValue: entry,
|
||||
name: StringUtils.cleanCliphistEntry(entry),
|
||||
verb: "",
|
||||
type: type,
|
||||
execute: () => {
|
||||
Cliphist.copy(entry);
|
||||
},
|
||||
actions: [resultComp.createObject(null, {
|
||||
name: Translation.tr("Copy"),
|
||||
iconName: "content_copy",
|
||||
iconType: LauncherSearchResult.IconType.Material,
|
||||
execute: () => {
|
||||
Cliphist.copy(entry);
|
||||
}
|
||||
}), resultComp.createObject(null, {
|
||||
name: Translation.tr("Delete"),
|
||||
iconName: "delete",
|
||||
iconType: LauncherSearchResult.IconType.Material,
|
||||
execute: () => {
|
||||
Cliphist.deleteEntry(entry);
|
||||
}
|
||||
})],
|
||||
blurImage: shouldBlurImage
|
||||
});
|
||||
}).filter(Boolean);
|
||||
} else if (root.query.startsWith(Config.options.search.prefix.emojis)) {
|
||||
const searchString = StringUtils.cleanPrefix(root.query, Config.options.search.prefix.emojis);
|
||||
const allEmojiStrings = [searchString, ...KeymapTranslation.translateAll(searchString)];
|
||||
const seenEmojis = new Set();
|
||||
const emojiEntries = allEmojiStrings.reduce((acc, q) => {
|
||||
return acc.concat(Emojis.fuzzyQuery(q).filter(entry => {
|
||||
const key = entry.match(/^\s*(\S+)/)?.[1] || entry;
|
||||
if (seenEmojis.has(key)) return false;
|
||||
seenEmojis.add(key);
|
||||
return true;
|
||||
}));
|
||||
}, []);
|
||||
return emojiEntries.map(entry => {
|
||||
const emoji = entry.match(/^\s*(\S+)/)?.[1] || "";
|
||||
return resultComp.createObject(null, {
|
||||
rawValue: entry,
|
||||
name: entry.replace(/^\s*\S+\s+/, ""),
|
||||
iconName: emoji,
|
||||
iconType: LauncherSearchResult.IconType.Text,
|
||||
verb: Translation.tr("Copy"),
|
||||
type: Translation.tr("Emoji"),
|
||||
execute: () => {
|
||||
Quickshell.clipboardText = entry.match(/^\s*(\S+)/)?.[1];
|
||||
}
|
||||
});
|
||||
}).filter(Boolean);
|
||||
}
|
||||
|
||||
////////////////// Init ///////////////////
|
||||
nonAppResultsTimer.restart();
|
||||
const mathResultObject = resultComp.createObject(null, {
|
||||
name: root.mathResult,
|
||||
verb: Translation.tr("Copy"),
|
||||
type: Translation.tr("Math result"),
|
||||
fontType: LauncherSearchResult.FontType.Monospace,
|
||||
iconName: 'calculate',
|
||||
iconType: LauncherSearchResult.IconType.Material,
|
||||
execute: () => {
|
||||
Quickshell.clipboardText = root.mathResult;
|
||||
}
|
||||
});
|
||||
|
||||
const _appQuery = StringUtils.cleanPrefix(root.query, Config.options.search.prefix.app);
|
||||
const _primaryEntries = AppSearch.fuzzyQuery(_appQuery);
|
||||
const _seenIds = new Set(_primaryEntries.map(e => e.id));
|
||||
const _layoutEntries = KeymapTranslation.translateAll(_appQuery).reduce((acc, tq) => {
|
||||
return acc.concat(AppSearch.fuzzyQuery(tq).filter(e => {
|
||||
if (_seenIds.has(e.id)) return false;
|
||||
_seenIds.add(e.id);
|
||||
return true;
|
||||
}));
|
||||
}, []);
|
||||
const _translitQuery = KeymapTranslation.transliterate(_appQuery);
|
||||
const _translitEntries = (_translitQuery && _translitQuery !== _appQuery)
|
||||
? AppSearch.levenshteinQuery(_translitQuery).filter(e => {
|
||||
if (_seenIds.has(e.id)) return false;
|
||||
_seenIds.add(e.id);
|
||||
return true;
|
||||
})
|
||||
: [];
|
||||
const _typoEntries = (_primaryEntries.length === 0 && _layoutEntries.length === 0 && _translitEntries.length === 0)
|
||||
? AppSearch.levenshteinQuery(_appQuery).filter(e => {
|
||||
if (_seenIds.has(e.id)) return false;
|
||||
_seenIds.add(e.id);
|
||||
return true;
|
||||
})
|
||||
: [];
|
||||
const appResultObjects = [..._primaryEntries, ..._layoutEntries, ..._translitEntries, ..._typoEntries].map(entry => {
|
||||
return resultComp.createObject(null, {
|
||||
type: Translation.tr("App"),
|
||||
id: entry.id,
|
||||
name: entry.name,
|
||||
iconName: entry.icon,
|
||||
iconType: LauncherSearchResult.IconType.System,
|
||||
verb: Translation.tr("Open"),
|
||||
execute: () => {
|
||||
if (!entry.runInTerminal)
|
||||
entry.execute();
|
||||
else {
|
||||
// Fixed: Escape each argument individually and pass as separate tokens to -e
|
||||
Quickshell.execDetached(["bash", '-c', `${Config.options.apps.terminal} -e ${entry.command.map(arg => "'" + StringUtils.shellSingleQuoteEscape(arg) + "'").join(' ')}`]);
|
||||
}
|
||||
},
|
||||
comment: entry.comment,
|
||||
runInTerminal: entry.runInTerminal,
|
||||
genericName: entry.genericName,
|
||||
keywords: entry.keywords,
|
||||
actions: entry.actions.map(action => {
|
||||
return resultComp.createObject(null, {
|
||||
name: action.name,
|
||||
iconName: action.icon,
|
||||
iconType: LauncherSearchResult.IconType.System,
|
||||
execute: () => {
|
||||
if (!action.runInTerminal)
|
||||
action.execute();
|
||||
else {
|
||||
Quickshell.execDetached(["bash", '-c', `${Config.options.apps.terminal} -e ${action.command.map(arg => "'" + StringUtils.shellSingleQuoteEscape(arg) + "'").join(' ')}`]);
|
||||
}
|
||||
}
|
||||
});
|
||||
})
|
||||
});
|
||||
});
|
||||
|
||||
const commandResultObject = resultComp.createObject(null, {
|
||||
name: StringUtils.cleanPrefix(root.query, Config.options.search.prefix.shellCommand).replace("file://", ""),
|
||||
verb: Translation.tr("Run"),
|
||||
type: Translation.tr("Command"),
|
||||
fontType: LauncherSearchResult.FontType.Monospace,
|
||||
iconName: 'terminal',
|
||||
iconType: LauncherSearchResult.IconType.Material,
|
||||
execute: () => {
|
||||
let cleanedCommand = root.query.replace("file://", "");
|
||||
cleanedCommand = StringUtils.cleanPrefix(cleanedCommand, Config.options.search.prefix.shellCommand);
|
||||
if (cleanedCommand.startsWith(Config.options.search.prefix.shellCommand)) {
|
||||
cleanedCommand = cleanedCommand.slice(Config.options.search.prefix.shellCommand.length);
|
||||
}
|
||||
Quickshell.execDetached(["bash", "-c", root.query.startsWith('sudo') ? `${Config.options.apps.terminal} fish -C '${cleanedCommand}'` : cleanedCommand]);
|
||||
}
|
||||
});
|
||||
const webSearchResultObject = resultComp.createObject(null, {
|
||||
name: StringUtils.cleanPrefix(root.query, Config.options.search.prefix.webSearch),
|
||||
verb: Translation.tr("Search"),
|
||||
type: Translation.tr("Web search"),
|
||||
iconName: 'travel_explore',
|
||||
iconType: LauncherSearchResult.IconType.Material,
|
||||
execute: () => {
|
||||
let query = StringUtils.cleanPrefix(root.query, Config.options.search.prefix.webSearch);
|
||||
let url = Config.options.search.engineBaseUrl + query;
|
||||
for (let site of Config.options.search.excludedSites) {
|
||||
url += ` -site:${site}`;
|
||||
}
|
||||
Qt.openUrlExternally(url);
|
||||
}
|
||||
});
|
||||
const launcherActionObjects = root.allActions.map(action => {
|
||||
const actionString = `${Config.options.search.prefix.action}${action.action}`;
|
||||
if (actionString.startsWith(root.query) || root.query.startsWith(actionString)) {
|
||||
return resultComp.createObject(null, {
|
||||
name: root.query.startsWith(actionString) ? root.query : actionString,
|
||||
verb: Translation.tr("Run"),
|
||||
type: Translation.tr("Action"),
|
||||
iconName: 'settings_suggest',
|
||||
iconType: LauncherSearchResult.IconType.Material,
|
||||
execute: () => {
|
||||
action.execute(root.query.split(" ").slice(1).join(" "));
|
||||
}
|
||||
});
|
||||
}
|
||||
return null;
|
||||
}).filter(Boolean);
|
||||
|
||||
//////// Prioritized by prefix /////////
|
||||
let result = [];
|
||||
const startsWithNumber = /^\d/.test(root.query);
|
||||
const startsWithMathPrefix = root.query.startsWith(Config.options.search.prefix.math);
|
||||
const startsWithShellCommandPrefix = root.query.startsWith(Config.options.search.prefix.shellCommand);
|
||||
const startsWithWebSearchPrefix = root.query.startsWith(Config.options.search.prefix.webSearch);
|
||||
if (startsWithNumber || startsWithMathPrefix) {
|
||||
result.push(mathResultObject);
|
||||
} else if (startsWithShellCommandPrefix) {
|
||||
result.push(commandResultObject);
|
||||
} else if (startsWithWebSearchPrefix) {
|
||||
result.push(webSearchResultObject);
|
||||
}
|
||||
|
||||
//////////////// Apps //////////////////
|
||||
result = result.concat(appResultObjects);
|
||||
result = result.concat(fileResults);
|
||||
|
||||
|
||||
////////// Launcher actions ////////////
|
||||
result = result.concat(launcherActionObjects);
|
||||
|
||||
/// Math result, command, web search ///
|
||||
if (Config.options.search.prefix.showDefaultActionsWithoutPrefix) {
|
||||
if (!startsWithShellCommandPrefix)
|
||||
result.push(commandResultObject);
|
||||
if (!startsWithNumber && !startsWithMathPrefix)
|
||||
result.push(mathResultObject);
|
||||
if (!startsWithWebSearchPrefix)
|
||||
result.push(webSearchResultObject);
|
||||
}
|
||||
|
||||
return result;
|
||||
}
|
||||
|
||||
Component {
|
||||
id: resultComp
|
||||
LauncherSearchResult {}
|
||||
}
|
||||
}
|
||||
Loading…
Reference in a new issue