publish: the public projection begins here

This is a projection, not a development branch. The tree above was constructed
from the internal source named below under a manifest that decides which paths
may leave, then scanned as a whole tree rather than as a series of patches, and
only then published.

Public history starts here because the history before it was not admissible,
and neither was the tree. What used to stand in this repository included a
rescue copy of another machine, a directory of phone handoffs, deployment
wired to one house, and a submodule pointing at a forge no stranger can reach.
None of that was ever the product. It stays in the private forge, which is
allowed to hold the whole working organism, and this is what was deliberately
sent out instead.

Three mechanisms produced this tree, in decreasing order of trust. A top-level
path the manifest does not name never arrives at all, which is the one that
catches directories nobody has thought of yet. Named internal files inside
admitted roots are dropped. A short, reviewed table replaces deployment
defaults that a public build must not carry -- an endpoint aimed at one LAN, a
VPN profile belonging to one phone, packaging built from one checkout path.

Everything after this commit is an ordinary publication with the same three
trailers, so a force push stops being routine and starts meaning that
something deliberate happened. The trailers bind the projection to its source
without pretending the public SHA is the private one: same lineage, different
tree, and the record says so.

Source-Sha: 8f27b1e76a8fef560a336aba18e6990713ff1047
Policy-Sha: 6b261d2f3e6e1fb19874846ba4bb1dfe15565d25b8618c1c1afba0419c101d27
Tree-Digest: 18ec3563c5e5ef9a414993a9f6734b251ff9ed3cd56eebdd6cac01e45c6e3067

surfaces/quickshell/ii-phone/services/Audio.qml

@@ -0,0 +1,139 @@
+pragma Singleton
+pragma ComponentBehavior: Bound
+import qs.modules.common
+import QtQuick
+import Quickshell
+import Quickshell.Services.Pipewire
+
+/**
+ * A nice wrapper for default Pipewire audio sink and source.
+ */
+Singleton {
+    id: root
+
+    // Misc props
+    property bool ready: Pipewire.defaultAudioSink?.ready ?? false
+    property PwNode sink: Pipewire.defaultAudioSink
+    property PwNode source: Pipewire.defaultAudioSource
+    readonly property real hardMaxValue: 2.00 // People keep joking about setting volume to 5172% so...
+    property string audioTheme: Config.options.sounds.theme
+    property real value: sink?.audio.volume ?? 0
+
+    function friendlyDeviceName(node) {
+        return (node.nickname || node.description || Translation.tr("Unknown"));
+    }
+    function appNodeDisplayName(node) {
+        return (node.properties["application.name"] || node.description || node.name)
+    }
+
+    // Lists
+    function correctType(node, isSink) {
+        return (node.isSink === isSink) && node.audio
+    }
+    function appNodes(isSink) {
+        return Pipewire.nodes.values.filter((node) => { // Should be list<PwNode> but it breaks ScriptModel
+            return root.correctType(node, isSink) && node.isStream
+        })
+    }
+    function devices(isSink) {
+        return Pipewire.nodes.values.filter(node => {
+            return root.correctType(node, isSink) && !node.isStream
+        })
+    }
+    readonly property list<var> outputAppNodes: root.appNodes(true)
+    readonly property list<var> inputAppNodes: root.appNodes(false)
+    readonly property list<var> outputDevices: root.devices(true)
+    readonly property list<var> inputDevices: root.devices(false)
+
+    // Signals
+    signal sinkProtectionTriggered(string reason);
+
+    // Controls
+    function toggleMute() {
+        Audio.sink.audio.muted = !Audio.sink.audio.muted
+    }
+
+    function toggleMicMute() {
+        Audio.source.audio.muted = !Audio.source.audio.muted
+    }
+
+    function incrementVolume() {
+        const currentVolume = Audio.value;
+        const step = currentVolume < 0.1 ? 0.01 : 0.02 || 0.2;
+        Audio.sink.audio.volume = Math.min(1, Audio.sink.audio.volume + step);
+    }
+
+    function decrementVolume() {
+        const currentVolume = Audio.value;
+        const step = currentVolume < 0.1 ? 0.01 : 0.02 || 0.2;
+        Audio.sink.audio.volume -= step;
+    }
+
+    function setDefaultSink(node) {
+        Pipewire.preferredDefaultAudioSink = node;
+    }
+
+    function setDefaultSource(node) {
+        Pipewire.preferredDefaultAudioSource = node;
+    }
+
+    // Internals
+    PwObjectTracker {
+        objects: [sink, source]
+    }
+
+    Connections { // Protection against sudden volume changes
+        target: sink?.audio ?? null
+        property bool lastReady: false
+        property real lastVolume: 0
+        function onVolumeChanged() {
+            if (!Config.options.audio.protection.enable) return;
+            const newVolume = sink.audio.volume;
+            // when resuming from suspend, we should not write volume to avoid pipewire volume reset issues
+            if (isNaN(newVolume) || newVolume === undefined || newVolume === null) {
+                lastReady = false;
+                lastVolume = 0;
+                return;
+            }
+            if (!lastReady) {
+                lastVolume = newVolume;
+                lastReady = true;
+                return;
+            }
+            const maxAllowedIncrease = Config.options.audio.protection.maxAllowedIncrease / 100;
+            const maxAllowed = Config.options.audio.protection.maxAllowed / 100;
+
+            if (newVolume - lastVolume > maxAllowedIncrease) {
+                sink.audio.volume = lastVolume;
+                root.sinkProtectionTriggered(Translation.tr("Illegal increment"));
+            } else if (newVolume > maxAllowed || newVolume > root.hardMaxValue) {
+                root.sinkProtectionTriggered(Translation.tr("Exceeded max allowed"));
+                sink.audio.volume = Math.min(lastVolume, maxAllowed);
+            }
+            lastVolume = sink.audio.volume;
+        }
+    }
+
+    function playSystemSound(soundName) {
+        const ogaPath = `/usr/share/sounds/${root.audioTheme}/stereo/${soundName}.oga`;
+        const oggPath = `/usr/share/sounds/${root.audioTheme}/stereo/${soundName}.ogg`;
+
+        // Try playing .oga first
+        let command = [
+            "ffplay",
+            "-nodisp",
+            "-autoexit",
+            ogaPath
+        ];
+        Quickshell.execDetached(command);
+
+        // Also try playing .ogg (ffplay will just fail silently if file doesn't exist)
+        command = [
+            "ffplay",
+            "-nodisp",
+            "-autoexit",
+            oggPath
+        ];
+        Quickshell.execDetached(command);
+    }
+}