surfaces/quickshell: adopt OSK flee-fix sidebars, focus-grab service, systemd hypridle
This commit is contained in:
Fimeg
parent
2c218fb075
commit
bebb5a2382
5 changed files with 540 additions and 0 deletions
|
|
@ -21,6 +21,10 @@ MANIFEST="
|
|||
services/Souveraine.qml ii/services/Souveraine.qml
|
||||
services/Ai.qml ii/services/Ai.qml
|
||||
services/TaskbarApps.qml ii/services/TaskbarApps.qml
|
||||
services/GlobalFocusGrab.qml ii/services/GlobalFocusGrab.qml
|
||||
services/Idle.qml ii/services/Idle.qml
|
||||
modules/ii/sidebarLeft/SidebarLeft.qml ii/modules/ii/sidebarLeft/SidebarLeft.qml
|
||||
modules/ii/sidebarRight/SidebarRight.qml ii/modules/ii/sidebarRight/SidebarRight.qml
|
||||
modules/common/Config.qml ii/modules/common/Config.qml
|
||||
modules/ii/dock/Dock.qml ii/modules/ii/dock/Dock.qml
|
||||
modules/ii/dock/DockApps.qml ii/modules/ii/dock/DockApps.qml
|
||||
|
|
|
|||
271
surfaces/quickshell/modules/ii/sidebarLeft/SidebarLeft.qml
Normal file
271
surfaces/quickshell/modules/ii/sidebarLeft/SidebarLeft.qml
Normal file
|
|
@ -0,0 +1,271 @@
|
|||
import qs
|
||||
import qs.services
|
||||
import qs.modules.common
|
||||
import qs.modules.common.widgets
|
||||
import QtQuick
|
||||
import Quickshell.Io
|
||||
import Quickshell
|
||||
import Quickshell.Wayland
|
||||
import Quickshell.Hyprland
|
||||
|
||||
Scope { // Scope
|
||||
id: root
|
||||
property bool detach: false
|
||||
property bool pin: false
|
||||
property Component contentComponent: SidebarLeftContent {}
|
||||
property Item sidebarContent
|
||||
|
||||
function toggleDetach() {
|
||||
root.detach = !root.detach;
|
||||
}
|
||||
|
||||
Process { // Dodge cursor away, pin, move cursor back
|
||||
id: pinWithFunnyHyprlandWorkaroundProc
|
||||
property var hook: null
|
||||
property int cursorX;
|
||||
property int cursorY;
|
||||
function doIt() {
|
||||
command = ["hyprctl", "cursorpos"]
|
||||
hook = (output) => {
|
||||
cursorX = parseInt(output.split(",")[0]);
|
||||
cursorY = parseInt(output.split(",")[1]);
|
||||
doIt2();
|
||||
}
|
||||
running = true;
|
||||
}
|
||||
function doIt2(output) {
|
||||
command = ["bash", "-c", "hyprctl dispatch 'hl.dsp.cursor.move({x=9999,y=9999})'"];
|
||||
hook = () => {
|
||||
doIt3();
|
||||
}
|
||||
running = true;
|
||||
}
|
||||
function doIt3(output) {
|
||||
root.pin = !root.pin;
|
||||
command = ["bash", "-c", `sleep 0.01; hyprctl dispatch 'hl.dsp.cursor.move({x=${cursorX},y=${cursorY}})'`];
|
||||
hook = null
|
||||
running = true;
|
||||
}
|
||||
stdout: StdioCollector {
|
||||
onStreamFinished: {
|
||||
pinWithFunnyHyprlandWorkaroundProc.hook(text);
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
function togglePin() {
|
||||
if (!root.pin) pinWithFunnyHyprlandWorkaroundProc.doIt()
|
||||
else root.pin = !root.pin;
|
||||
}
|
||||
|
||||
Component.onCompleted: {
|
||||
root.sidebarContent = contentComponent.createObject(null, {
|
||||
"scopeRoot": root,
|
||||
});
|
||||
sidebarLoader.item.contentParent.children = [root.sidebarContent];
|
||||
}
|
||||
|
||||
onDetachChanged: {
|
||||
if (root.detach) {
|
||||
GlobalFocusGrab.removeDismissable(sidebarLoader.item) // Remove sidebar from the focus grab system
|
||||
sidebarContent.parent = null; // Detach content from sidebar
|
||||
sidebarLoader.active = false; // Unload sidebar
|
||||
detachedSidebarLoader.active = true; // Load detached window
|
||||
detachedSidebarLoader.item.contentParent.children = [sidebarContent];
|
||||
} else {
|
||||
sidebarContent.parent = null; // Detach content from window
|
||||
detachedSidebarLoader.active = false; // Unload detached window
|
||||
sidebarLoader.active = true; // Load sidebar
|
||||
sidebarLoader.item.contentParent.children = [sidebarContent];
|
||||
}
|
||||
}
|
||||
|
||||
Loader {
|
||||
id: sidebarLoader
|
||||
active: true
|
||||
|
||||
sourceComponent: PanelWindow { // Window
|
||||
id: panelWindow
|
||||
visible: GlobalStates.sidebarLeftOpen
|
||||
|
||||
property bool extend: false
|
||||
property real sidebarWidth: panelWindow.extend ? Appearance.sizes.sidebarWidthExtended : Appearance.sizes.sidebarWidth
|
||||
property var contentParent: sidebarLeftBackground
|
||||
|
||||
function hide() {
|
||||
GlobalStates.sidebarLeftOpen = false
|
||||
}
|
||||
|
||||
exclusionMode: ExclusionMode.Normal
|
||||
exclusiveZone: root.pin ? sidebarWidth : 0
|
||||
implicitWidth: Appearance.sizes.sidebarWidthExtended + Appearance.sizes.elevationMargin
|
||||
WlrLayershell.namespace: "quickshell:sidebarLeft"
|
||||
// Hyprland 0.49: OnDemand is Exclusive, Exclusive just breaks click-outside-to-close
|
||||
WlrLayershell.keyboardFocus: WlrKeyboardFocus.OnDemand
|
||||
color: "transparent"
|
||||
|
||||
anchors {
|
||||
top: true
|
||||
left: true
|
||||
bottom: true
|
||||
}
|
||||
|
||||
mask: Region {
|
||||
item: sidebarLeftBackground
|
||||
}
|
||||
|
||||
onVisibleChanged: {
|
||||
if (visible && !GlobalStates.oskOpen) {
|
||||
GlobalFocusGrab.addDismissable(panelWindow);
|
||||
} else {
|
||||
GlobalFocusGrab.removeDismissable(panelWindow);
|
||||
}
|
||||
}
|
||||
Connections {
|
||||
target: GlobalFocusGrab
|
||||
function onDismissed() {
|
||||
panelWindow.hide();
|
||||
}
|
||||
}
|
||||
|
||||
// OSK flee-fix: squeekboard is an external surface not in the
|
||||
// HyprlandFocusGrab whitelist; typing on it clears the grab and
|
||||
// hides this panel. While the OSK is open, leave the dismissable
|
||||
// set so there is nothing to clear. Mirrors Overview.qml.
|
||||
Connections {
|
||||
target: GlobalStates
|
||||
function onOskOpenChanged() {
|
||||
if (!GlobalStates.sidebarLeftOpen) return;
|
||||
if (GlobalStates.oskOpen) {
|
||||
GlobalFocusGrab.removeDismissable(panelWindow);
|
||||
} else {
|
||||
GlobalFocusGrab.addDismissable(panelWindow);
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
// Content
|
||||
StyledRectangularShadow {
|
||||
target: sidebarLeftBackground
|
||||
radius: sidebarLeftBackground.radius
|
||||
}
|
||||
Rectangle {
|
||||
id: sidebarLeftBackground
|
||||
anchors.top: parent.top
|
||||
anchors.left: parent.left
|
||||
anchors.topMargin: Appearance.sizes.hyprlandGapsOut
|
||||
anchors.leftMargin: Appearance.sizes.hyprlandGapsOut
|
||||
width: panelWindow.sidebarWidth - Appearance.sizes.hyprlandGapsOut - Appearance.sizes.elevationMargin
|
||||
height: parent.height - Appearance.sizes.hyprlandGapsOut * 2
|
||||
color: Appearance.colors.colLayer0
|
||||
border.width: 1
|
||||
border.color: Appearance.colors.colLayer0Border
|
||||
radius: Appearance.rounding.screenRounding - Appearance.sizes.hyprlandGapsOut + 1
|
||||
|
||||
Behavior on width {
|
||||
animation: Appearance.animation.elementMove.numberAnimation.createObject(this)
|
||||
}
|
||||
|
||||
Keys.onPressed: (event) => {
|
||||
if (event.key === Qt.Key_Escape) {
|
||||
panelWindow.hide();
|
||||
}
|
||||
if (event.modifiers === Qt.ControlModifier) {
|
||||
if (event.key === Qt.Key_O) {
|
||||
panelWindow.extend = !panelWindow.extend;
|
||||
} else if (event.key === Qt.Key_D) {
|
||||
root.toggleDetach();
|
||||
} else if (event.key === Qt.Key_P) {
|
||||
root.togglePin();
|
||||
}
|
||||
event.accepted = true;
|
||||
}
|
||||
}
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
Loader {
|
||||
id: detachedSidebarLoader
|
||||
active: false
|
||||
|
||||
sourceComponent: FloatingWindow {
|
||||
id: detachedSidebarRoot
|
||||
property var contentParent: detachedSidebarBackground
|
||||
color: "transparent"
|
||||
|
||||
visible: GlobalStates.sidebarLeftOpen
|
||||
onVisibleChanged: {
|
||||
if (!visible) GlobalStates.sidebarLeftOpen = false;
|
||||
}
|
||||
|
||||
Rectangle {
|
||||
id: detachedSidebarBackground
|
||||
anchors.fill: parent
|
||||
color: Appearance.colors.colLayer0
|
||||
|
||||
Keys.onPressed: (event) => {
|
||||
if (event.modifiers === Qt.ControlModifier) {
|
||||
if (event.key === Qt.Key_D) {
|
||||
root.toggleDetach();
|
||||
}
|
||||
event.accepted = true;
|
||||
}
|
||||
}
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
IpcHandler {
|
||||
target: "sidebarLeft"
|
||||
|
||||
function toggle(): void {
|
||||
GlobalStates.sidebarLeftOpen = !GlobalStates.sidebarLeftOpen
|
||||
}
|
||||
|
||||
function close(): void {
|
||||
GlobalStates.sidebarLeftOpen = false
|
||||
}
|
||||
|
||||
function open(): void {
|
||||
GlobalStates.sidebarLeftOpen = true
|
||||
}
|
||||
}
|
||||
|
||||
GlobalShortcut {
|
||||
name: "sidebarLeftToggle"
|
||||
description: "Toggles left sidebar on press"
|
||||
|
||||
onPressed: {
|
||||
GlobalStates.sidebarLeftOpen = !GlobalStates.sidebarLeftOpen;
|
||||
}
|
||||
}
|
||||
|
||||
GlobalShortcut {
|
||||
name: "sidebarLeftOpen"
|
||||
description: "Opens left sidebar on press"
|
||||
|
||||
onPressed: {
|
||||
GlobalStates.sidebarLeftOpen = true;
|
||||
}
|
||||
}
|
||||
|
||||
GlobalShortcut {
|
||||
name: "sidebarLeftClose"
|
||||
description: "Closes left sidebar on press"
|
||||
|
||||
onPressed: {
|
||||
GlobalStates.sidebarLeftOpen = false;
|
||||
}
|
||||
}
|
||||
|
||||
GlobalShortcut {
|
||||
name: "sidebarLeftToggleDetach"
|
||||
description: "Detach left sidebar into a window/Attach it back"
|
||||
|
||||
onPressed: {
|
||||
root.detach = !root.detach;
|
||||
}
|
||||
}
|
||||
|
||||
}
|
||||
126
surfaces/quickshell/modules/ii/sidebarRight/SidebarRight.qml
Normal file
126
surfaces/quickshell/modules/ii/sidebarRight/SidebarRight.qml
Normal file
|
|
@ -0,0 +1,126 @@
|
|||
import qs
|
||||
import qs.services
|
||||
import qs.modules.common
|
||||
import QtQuick
|
||||
import Quickshell.Io
|
||||
import Quickshell
|
||||
import Quickshell.Wayland
|
||||
import Quickshell.Hyprland
|
||||
|
||||
Scope {
|
||||
id: root
|
||||
property int sidebarWidth: Appearance.sizes.sidebarWidth
|
||||
|
||||
PanelWindow {
|
||||
id: panelWindow
|
||||
visible: GlobalStates.sidebarRightOpen
|
||||
|
||||
function hide() {
|
||||
GlobalStates.sidebarRightOpen = false;
|
||||
}
|
||||
|
||||
exclusiveZone: 0
|
||||
implicitWidth: sidebarWidth
|
||||
WlrLayershell.namespace: "quickshell:sidebarRight"
|
||||
WlrLayershell.keyboardFocus: GlobalStates.sidebarRightOpen ? WlrKeyboardFocus.OnDemand : WlrKeyboardFocus.None
|
||||
color: "transparent"
|
||||
|
||||
anchors {
|
||||
top: true
|
||||
right: true
|
||||
bottom: true
|
||||
}
|
||||
|
||||
onVisibleChanged: {
|
||||
if (visible && !GlobalStates.oskOpen) {
|
||||
GlobalFocusGrab.addDismissable(panelWindow);
|
||||
} else {
|
||||
GlobalFocusGrab.removeDismissable(panelWindow);
|
||||
}
|
||||
}
|
||||
Connections {
|
||||
target: GlobalFocusGrab
|
||||
function onDismissed() {
|
||||
panelWindow.hide();
|
||||
}
|
||||
}
|
||||
|
||||
// OSK flee-fix: squeekboard is an external surface not in the
|
||||
// HyprlandFocusGrab whitelist; typing on it clears the grab and
|
||||
// hides this panel. While the OSK is open, leave the dismissable
|
||||
// set so there is nothing to clear. Mirrors Overview.qml.
|
||||
Connections {
|
||||
target: GlobalStates
|
||||
function onOskOpenChanged() {
|
||||
if (!GlobalStates.sidebarRightOpen) return;
|
||||
if (GlobalStates.oskOpen) {
|
||||
GlobalFocusGrab.removeDismissable(panelWindow);
|
||||
} else {
|
||||
GlobalFocusGrab.addDismissable(panelWindow);
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
Loader {
|
||||
id: sidebarContentLoader
|
||||
active: GlobalStates.sidebarRightOpen || Config?.options.sidebar.keepRightSidebarLoaded
|
||||
anchors {
|
||||
fill: parent
|
||||
margins: Appearance.sizes.hyprlandGapsOut
|
||||
leftMargin: Appearance.sizes.elevationMargin
|
||||
}
|
||||
width: sidebarWidth - Appearance.sizes.hyprlandGapsOut - Appearance.sizes.elevationMargin
|
||||
height: parent.height - Appearance.sizes.hyprlandGapsOut * 2
|
||||
|
||||
focus: GlobalStates.sidebarRightOpen
|
||||
Keys.onPressed: event => {
|
||||
if (event.key === Qt.Key_Escape) {
|
||||
panelWindow.hide();
|
||||
}
|
||||
}
|
||||
|
||||
sourceComponent: SidebarRightContent {}
|
||||
}
|
||||
}
|
||||
|
||||
IpcHandler {
|
||||
target: "sidebarRight"
|
||||
|
||||
function toggle(): void {
|
||||
GlobalStates.sidebarRightOpen = !GlobalStates.sidebarRightOpen;
|
||||
}
|
||||
|
||||
function close(): void {
|
||||
GlobalStates.sidebarRightOpen = false;
|
||||
}
|
||||
|
||||
function open(): void {
|
||||
GlobalStates.sidebarRightOpen = true;
|
||||
}
|
||||
}
|
||||
|
||||
GlobalShortcut {
|
||||
name: "sidebarRightToggle"
|
||||
description: "Toggles right sidebar on press"
|
||||
|
||||
onPressed: {
|
||||
GlobalStates.sidebarRightOpen = !GlobalStates.sidebarRightOpen;
|
||||
}
|
||||
}
|
||||
GlobalShortcut {
|
||||
name: "sidebarRightOpen"
|
||||
description: "Opens right sidebar on press"
|
||||
|
||||
onPressed: {
|
||||
GlobalStates.sidebarRightOpen = true;
|
||||
}
|
||||
}
|
||||
GlobalShortcut {
|
||||
name: "sidebarRightClose"
|
||||
description: "Closes right sidebar on press"
|
||||
|
||||
onPressed: {
|
||||
GlobalStates.sidebarRightOpen = false;
|
||||
}
|
||||
}
|
||||
}
|
||||
72
surfaces/quickshell/services/GlobalFocusGrab.qml
Normal file
72
surfaces/quickshell/services/GlobalFocusGrab.qml
Normal file
|
|
@ -0,0 +1,72 @@
|
|||
pragma Singleton
|
||||
pragma ComponentBehavior: Bound
|
||||
import QtQuick
|
||||
import Quickshell
|
||||
import Quickshell.Hyprland
|
||||
|
||||
/**
|
||||
* Manages a HyprlandFocusGrab that's to be shared by all windows.
|
||||
* "Persistent" is for windows that should always be included but not closed on dismiss, like bar and onscreen keyboard.
|
||||
* "Dismissable" is for stuff like sidebars
|
||||
*/
|
||||
Singleton {
|
||||
id: root
|
||||
|
||||
signal dismissed()
|
||||
|
||||
property list<var> persistent: []
|
||||
property list<var> dismissable: []
|
||||
|
||||
function dismiss() {
|
||||
root.dismissable = [];
|
||||
root.dismissed();
|
||||
}
|
||||
|
||||
Component.onCompleted: {
|
||||
console.log("[GlobalFocusGrab] Initialized");
|
||||
}
|
||||
|
||||
function addPersistent(window) {
|
||||
if (root.persistent.indexOf(window) === -1) {
|
||||
root.persistent.push(window);
|
||||
}
|
||||
}
|
||||
|
||||
function removePersistent(window) {
|
||||
var index = root.persistent.indexOf(window);
|
||||
if (index !== -1) {
|
||||
root.persistent.splice(index, 1);
|
||||
}
|
||||
}
|
||||
|
||||
function addDismissable(window) {
|
||||
if (root.dismissable.indexOf(window) === -1) {
|
||||
root.dismissable.push(window);
|
||||
}
|
||||
}
|
||||
|
||||
function removeDismissable(window) {
|
||||
var index = root.dismissable.indexOf(window);
|
||||
if (index !== -1) {
|
||||
root.dismissable.splice(index, 1);
|
||||
}
|
||||
}
|
||||
|
||||
function hasActive(element) {
|
||||
return element?.activeFocus || Array.from(
|
||||
element?.children
|
||||
).some(
|
||||
(child) => hasActive(child)
|
||||
);
|
||||
}
|
||||
|
||||
HyprlandFocusGrab {
|
||||
id: grab
|
||||
windows: root.dismissable.every(w => !w?.focusable) || root.dismissable.some(w => hasActive(w?.contentItem)) ? [...root.dismissable, ...root.persistent] : [...root.dismissable]
|
||||
active: root.dismissable.length > 0
|
||||
onCleared: () => {
|
||||
root.dismiss();
|
||||
}
|
||||
}
|
||||
|
||||
}
|
||||
67
surfaces/quickshell/services/Idle.qml
Normal file
67
surfaces/quickshell/services/Idle.qml
Normal file
|
|
@ -0,0 +1,67 @@
|
|||
pragma Singleton
|
||||
import qs.modules.common
|
||||
import QtQuick
|
||||
import Quickshell
|
||||
import Quickshell.Wayland
|
||||
|
||||
/**
|
||||
* A nice wrapper for date and time strings.
|
||||
*/
|
||||
Singleton {
|
||||
id: root
|
||||
|
||||
property alias inhibit: idleInhibitor.enabled
|
||||
inhibit: false
|
||||
|
||||
// Pixel 3: the Wayland idle-inhibitor on an invisible 0x0 surface is
|
||||
// not honored by our compositor build, and screen-off is driven by
|
||||
// hypridle scripts anyway — so Keep System Awake stops/starts hypridle.
|
||||
onInhibitChanged: {
|
||||
// Keep System Awake toggles the systemd-managed hypridle unit.
|
||||
// (Was pkill/setsid, which orphaned hypridle across Hyprland restarts
|
||||
// and wedged wake — see hyprland.lua hyprland.start.)
|
||||
Quickshell.execDetached(["sh", "-c", root.inhibit
|
||||
? "systemctl --user stop hypridle.service"
|
||||
: "systemctl --user reset-failed hypridle.service 2>/dev/null; systemctl --user restart hypridle.service"])
|
||||
}
|
||||
|
||||
Connections {
|
||||
target: Persistent
|
||||
function onReadyChanged() {
|
||||
if (!Persistent.isNewHyprlandInstance) {
|
||||
root.inhibit = Persistent.states.idle.inhibit;
|
||||
} else {
|
||||
Persistent.states.idle.inhibit = root.inhibit;
|
||||
}
|
||||
}
|
||||
}
|
||||
|
||||
function toggleInhibit(active = null) {
|
||||
if (active !== null) {
|
||||
root.inhibit = active;
|
||||
} else {
|
||||
root.inhibit = !root.inhibit;
|
||||
}
|
||||
Persistent.states.idle.inhibit = root.inhibit;
|
||||
}
|
||||
|
||||
IdleInhibitor {
|
||||
id: idleInhibitor
|
||||
window: PanelWindow {
|
||||
// Inhibitor requires a "visible" surface
|
||||
// Actually not lol
|
||||
implicitWidth: 0
|
||||
implicitHeight: 0
|
||||
color: "transparent"
|
||||
// Just in case...
|
||||
anchors {
|
||||
right: true
|
||||
bottom: true
|
||||
}
|
||||
// Make it not interactable
|
||||
mask: Region {
|
||||
item: null
|
||||
}
|
||||
}
|
||||
}
|
||||
}
|
||||
Loading…
Reference in a new issue