8f42fc953d
This is a projection, not a development branch. The tree above was constructed from the internal source named below under a manifest that decides which paths may leave, then scanned as a whole tree rather than as a series of patches, and only then published. Public history starts here because the history before it was not admissible, and neither was the tree. What used to stand in this repository included a rescue copy of another machine, a directory of phone handoffs, deployment wired to one house, and a submodule pointing at a forge no stranger can reach. None of that was ever the product. It stays in the private forge, which is allowed to hold the whole working organism, and this is what was deliberately sent out instead. Three mechanisms produced this tree, in decreasing order of trust. A top-level path the manifest does not name never arrives at all, which is the one that catches directories nobody has thought of yet. Named internal files inside admitted roots are dropped. A short, reviewed table replaces deployment defaults that a public build must not carry -- an endpoint aimed at one LAN, a VPN profile belonging to one phone, packaging built from one checkout path. Everything after this commit is an ordinary publication with the same three trailers, so a force push stops being routine and starts meaning that something deliberate happened. The trailers bind the projection to its source without pretending the public SHA is the private one: same lineage, different tree, and the record says so. Source-Sha: 8f27b1e76a8fef560a336aba18e6990713ff1047 Policy-Sha: 6b261d2f3e6e1fb19874846ba4bb1dfe15565d25b8618c1c1afba0419c101d27 Tree-Digest: 18ec3563c5e5ef9a414993a9f6734b251ff9ed3cd56eebdd6cac01e45c6e3067
88 lines
2.5 KiB
QML
88 lines
2.5 KiB
QML
import QtQuick
|
|
import QtQuick.Shapes
|
|
import qs.modules.common
|
|
|
|
/**
|
|
* Material 3 circular progress. See https://m3.material.io/components/progress-indicators/specs
|
|
*/
|
|
Item {
|
|
id: root
|
|
|
|
property int implicitSize: 30
|
|
property int lineWidth: 2
|
|
property real value: 0
|
|
property color colPrimary: Appearance.m3colors.m3onSecondaryContainer
|
|
property color colSecondary: Appearance.colors.colSecondaryContainer
|
|
property real gapAngle: 360 / 18
|
|
property bool fill: false
|
|
property int fillOverflow: 2
|
|
property bool enableAnimation: true
|
|
property int animationDuration: 800
|
|
property var easingType: Easing.OutCubic
|
|
|
|
implicitWidth: implicitSize
|
|
implicitHeight: implicitSize
|
|
|
|
property real degree: value * 360
|
|
property real centerX: root.width / 2
|
|
property real centerY: root.height / 2
|
|
property real arcRadius: root.implicitSize / 2 - root.lineWidth
|
|
property real startAngle: -90
|
|
|
|
Behavior on degree {
|
|
enabled: root.enableAnimation
|
|
NumberAnimation {
|
|
duration: root.animationDuration
|
|
easing.type: root.easingType
|
|
}
|
|
|
|
}
|
|
|
|
Loader {
|
|
active: root.fill
|
|
anchors.fill: parent
|
|
|
|
sourceComponent: Rectangle {
|
|
radius: 9999
|
|
color: root.colSecondary
|
|
}
|
|
}
|
|
|
|
Shape {
|
|
anchors.fill: parent
|
|
layer.enabled: true
|
|
layer.smooth: true
|
|
preferredRendererType: Shape.CurveRenderer
|
|
ShapePath {
|
|
id: secondaryPath
|
|
strokeColor: root.colSecondary
|
|
strokeWidth: root.lineWidth
|
|
capStyle: ShapePath.RoundCap
|
|
fillColor: "transparent"
|
|
PathAngleArc {
|
|
centerX: root.centerX
|
|
centerY: root.centerY
|
|
radiusX: root.arcRadius
|
|
radiusY: root.arcRadius
|
|
startAngle: root.startAngle - root.gapAngle
|
|
sweepAngle: -(360 - root.degree - 2 * root.gapAngle)
|
|
}
|
|
}
|
|
ShapePath {
|
|
id: primaryPath
|
|
strokeColor: root.colPrimary
|
|
strokeWidth: root.lineWidth
|
|
capStyle: ShapePath.RoundCap
|
|
fillColor: "transparent"
|
|
PathAngleArc {
|
|
centerX: root.centerX
|
|
centerY: root.centerY
|
|
radiusX: root.arcRadius
|
|
radiusY: root.arcRadius
|
|
startAngle: root.startAngle
|
|
sweepAngle: root.degree
|
|
}
|
|
}
|
|
}
|
|
|
|
}
|