8f42fc953d
This is a projection, not a development branch. The tree above was constructed from the internal source named below under a manifest that decides which paths may leave, then scanned as a whole tree rather than as a series of patches, and only then published. Public history starts here because the history before it was not admissible, and neither was the tree. What used to stand in this repository included a rescue copy of another machine, a directory of phone handoffs, deployment wired to one house, and a submodule pointing at a forge no stranger can reach. None of that was ever the product. It stays in the private forge, which is allowed to hold the whole working organism, and this is what was deliberately sent out instead. Three mechanisms produced this tree, in decreasing order of trust. A top-level path the manifest does not name never arrives at all, which is the one that catches directories nobody has thought of yet. Named internal files inside admitted roots are dropped. A short, reviewed table replaces deployment defaults that a public build must not carry -- an endpoint aimed at one LAN, a VPN profile belonging to one phone, packaging built from one checkout path. Everything after this commit is an ordinary publication with the same three trailers, so a force push stops being routine and starts meaning that something deliberate happened. The trailers bind the projection to its source without pretending the public SHA is the private one: same lineage, different tree, and the record says so. Source-Sha: 8f27b1e76a8fef560a336aba18e6990713ff1047 Policy-Sha: 6b261d2f3e6e1fb19874846ba4bb1dfe15565d25b8618c1c1afba0419c101d27 Tree-Digest: 18ec3563c5e5ef9a414993a9f6734b251ff9ed3cd56eebdd6cac01e45c6e3067
175 lines
6.6 KiB
QML
175 lines
6.6 KiB
QML
import qs.modules.common
|
||
import qs.modules.common.widgets
|
||
import qs.modules.common.functions
|
||
import QtQuick
|
||
import QtQuick.Controls
|
||
import QtQuick.Layouts
|
||
|
||
TabButton {
|
||
id: root
|
||
|
||
property bool toggled: TabBar.tabBar.currentIndex === TabBar.index
|
||
property string buttonIcon
|
||
property string customIconSource: ""
|
||
property real buttonIconRotation: 0
|
||
property string buttonText
|
||
property bool expanded: false
|
||
property bool showCollapsedText: true
|
||
property bool animateLayout: true
|
||
property bool showToggledHighlight: true
|
||
readonly property bool showText: root.expanded || root.showCollapsedText
|
||
readonly property real visualWidth: root.expanded ? root.baseSize + 20 + itemText.implicitWidth : root.baseSize
|
||
|
||
property real baseSize: 56
|
||
property real baseHighlightHeight: 32
|
||
property real highlightCollapsedTopMargin: 8
|
||
padding: 0
|
||
|
||
// The navigation item’s target area always spans the full width of the
|
||
// nav rail, even if the item container hugs its contents.
|
||
Layout.fillWidth: true
|
||
// implicitWidth: contentItem.implicitWidth
|
||
implicitHeight: baseSize
|
||
|
||
background: null
|
||
PointingHandInteraction {}
|
||
|
||
// Real stuff
|
||
contentItem: Item {
|
||
id: buttonContent
|
||
anchors {
|
||
top: parent.top
|
||
bottom: parent.bottom
|
||
left: parent.left
|
||
right: undefined
|
||
}
|
||
|
||
implicitWidth: root.visualWidth
|
||
implicitHeight: root.expanded ? itemIconBackground.implicitHeight : itemIconBackground.implicitHeight + itemText.implicitHeight
|
||
|
||
Rectangle {
|
||
id: itemBackground
|
||
anchors.top: itemIconBackground.top
|
||
anchors.left: itemIconBackground.left
|
||
anchors.bottom: itemIconBackground.bottom
|
||
implicitWidth: root.visualWidth
|
||
radius: Appearance.rounding.full
|
||
color: toggled ?
|
||
root.showToggledHighlight ?
|
||
(root.down ? Appearance.colors.colSecondaryContainerActive : root.hovered ? Appearance.colors.colSecondaryContainerHover : Appearance.colors.colSecondaryContainer)
|
||
: ColorUtils.transparentize(Appearance.colors.colSecondaryContainer) :
|
||
(root.down ? Appearance.colors.colLayer1Active : root.hovered ? Appearance.colors.colLayer1Hover : ColorUtils.transparentize(Appearance.colors.colLayer1Hover, 1))
|
||
|
||
states: State {
|
||
name: "expanded"
|
||
when: root.expanded
|
||
AnchorChanges {
|
||
target: itemBackground
|
||
anchors.top: buttonContent.top
|
||
anchors.left: buttonContent.left
|
||
anchors.bottom: buttonContent.bottom
|
||
}
|
||
PropertyChanges {
|
||
target: itemBackground
|
||
implicitWidth: root.visualWidth
|
||
}
|
||
}
|
||
transitions: Transition {
|
||
enabled: root.animateLayout
|
||
AnchorAnimation {
|
||
duration: Appearance.animation.elementMoveFast.duration
|
||
easing.type: Appearance.animation.elementMoveFast.type
|
||
easing.bezierCurve: Appearance.animation.elementMoveFast.bezierCurve
|
||
}
|
||
PropertyAnimation {
|
||
target: itemBackground
|
||
property: "implicitWidth"
|
||
duration: Appearance.animation.elementMove.duration
|
||
easing.type: Appearance.animation.elementMove.type
|
||
easing.bezierCurve: Appearance.animation.elementMove.bezierCurve
|
||
}
|
||
}
|
||
|
||
Behavior on color {
|
||
animation: Appearance.animation.elementMoveFast.colorAnimation.createObject(this)
|
||
}
|
||
}
|
||
|
||
Item {
|
||
id: itemIconBackground
|
||
implicitWidth: root.baseSize
|
||
implicitHeight: root.baseHighlightHeight
|
||
anchors {
|
||
left: parent.left
|
||
verticalCenter: parent.verticalCenter
|
||
}
|
||
MaterialSymbol {
|
||
id: navRailButtonIcon
|
||
visible: root.customIconSource === ""
|
||
rotation: root.buttonIconRotation
|
||
anchors.centerIn: parent
|
||
iconSize: 24
|
||
fill: toggled ? 1 : 0
|
||
font.weight: (toggled || root.hovered) ? Font.DemiBold : Font.Normal
|
||
text: buttonIcon
|
||
color: toggled ? Appearance.m3colors.m3onSecondaryContainer : Appearance.colors.colOnLayer1
|
||
|
||
Behavior on color {
|
||
animation: Appearance.animation.elementMoveFast.colorAnimation.createObject(this)
|
||
}
|
||
}
|
||
Loader {
|
||
active: root.customIconSource !== ""
|
||
anchors.centerIn: parent
|
||
width: 24
|
||
height: 24
|
||
sourceComponent: CustomIcon {
|
||
width: 24
|
||
height: 24
|
||
source: root.customIconSource
|
||
colorize: true
|
||
color: toggled ? Appearance.m3colors.m3onSecondaryContainer : Appearance.colors.colOnLayer1
|
||
}
|
||
}
|
||
}
|
||
|
||
StyledText {
|
||
id: itemText
|
||
visible: root.showText
|
||
anchors {
|
||
top: itemIconBackground.bottom
|
||
topMargin: 2
|
||
horizontalCenter: itemIconBackground.horizontalCenter
|
||
}
|
||
states: State {
|
||
name: "expanded"
|
||
when: root.expanded
|
||
AnchorChanges {
|
||
target: itemText
|
||
anchors {
|
||
top: undefined
|
||
horizontalCenter: undefined
|
||
left: itemIconBackground.right
|
||
verticalCenter: itemIconBackground.verticalCenter
|
||
}
|
||
}
|
||
}
|
||
transitions: Transition {
|
||
enabled: root.animateLayout
|
||
AnchorAnimation {
|
||
duration: Appearance.animation.elementMoveFast.duration
|
||
easing.type: Appearance.animation.elementMoveFast.type
|
||
easing.bezierCurve: Appearance.animation.elementMoveFast.bezierCurve
|
||
}
|
||
}
|
||
text: buttonText
|
||
font.pixelSize: 14
|
||
color: Appearance.colors.colOnLayer1
|
||
opacity: root.showText ? 1 : 0
|
||
Behavior on opacity {
|
||
animation: Appearance.animation.elementMoveFast.numberAnimation.createObject(this)
|
||
}
|
||
}
|
||
}
|
||
|
||
}
|