8f42fc953d
This is a projection, not a development branch. The tree above was constructed from the internal source named below under a manifest that decides which paths may leave, then scanned as a whole tree rather than as a series of patches, and only then published. Public history starts here because the history before it was not admissible, and neither was the tree. What used to stand in this repository included a rescue copy of another machine, a directory of phone handoffs, deployment wired to one house, and a submodule pointing at a forge no stranger can reach. None of that was ever the product. It stays in the private forge, which is allowed to hold the whole working organism, and this is what was deliberately sent out instead. Three mechanisms produced this tree, in decreasing order of trust. A top-level path the manifest does not name never arrives at all, which is the one that catches directories nobody has thought of yet. Named internal files inside admitted roots are dropped. A short, reviewed table replaces deployment defaults that a public build must not carry -- an endpoint aimed at one LAN, a VPN profile belonging to one phone, packaging built from one checkout path. Everything after this commit is an ordinary publication with the same three trailers, so a force push stops being routine and starts meaning that something deliberate happened. The trailers bind the projection to its source without pretending the public SHA is the private one: same lineage, different tree, and the record says so. Source-Sha: 8f27b1e76a8fef560a336aba18e6990713ff1047 Policy-Sha: 6b261d2f3e6e1fb19874846ba4bb1dfe15565d25b8618c1c1afba0419c101d27 Tree-Digest: 18ec3563c5e5ef9a414993a9f6734b251ff9ed3cd56eebdd6cac01e45c6e3067
99 lines
No EOL
3.5 KiB
QML
99 lines
No EOL
3.5 KiB
QML
import qs.modules.common
|
|
import qs.modules.common.functions
|
|
import Qt5Compat.GraphicalEffects
|
|
import QtQuick
|
|
import Quickshell
|
|
import Quickshell.Widgets
|
|
import Quickshell.Services.Notifications
|
|
|
|
MaterialShape { // App icon
|
|
id: root
|
|
property var appIcon: ""
|
|
property var summary: ""
|
|
property var urgency: NotificationUrgency.Normal
|
|
property bool isUrgent: urgency === NotificationUrgency.Critical
|
|
property var image: ""
|
|
property real materialIconScale: 0.57
|
|
property real appIconScale: 0.8
|
|
property real smallAppIconScale: 0.49
|
|
property real materialIconSize: implicitSize * materialIconScale
|
|
property real appIconSize: implicitSize * appIconScale
|
|
property real smallAppIconSize: implicitSize * smallAppIconScale
|
|
|
|
implicitSize: 38 * scale
|
|
property list<var> urgentShapes: [
|
|
MaterialShape.Shape.VerySunny,
|
|
MaterialShape.Shape.SoftBurst,
|
|
]
|
|
shape: isUrgent ? urgentShapes[Math.floor(Math.random() * urgentShapes.length)] : MaterialShape.Shape.Circle
|
|
|
|
color: isUrgent ? Appearance.colors.colPrimaryContainer : Appearance.colors.colSecondaryContainer
|
|
Loader {
|
|
id: materialSymbolLoader
|
|
active: root.appIcon == "" && root.image == ""
|
|
anchors.fill: parent
|
|
sourceComponent: MaterialSymbol {
|
|
text: {
|
|
const defaultIcon = NotificationUtils.findSuitableMaterialSymbol("")
|
|
const guessedIcon = NotificationUtils.findSuitableMaterialSymbol(root.summary)
|
|
return (root.urgency == NotificationUrgency.Critical && guessedIcon === defaultIcon) ?
|
|
"priority_high" : guessedIcon
|
|
}
|
|
anchors.fill: parent
|
|
color: isUrgent ? Appearance.colors.colOnPrimaryContainer : Appearance.colors.colOnSecondaryContainer
|
|
iconSize: root.materialIconSize
|
|
horizontalAlignment: Text.AlignHCenter
|
|
verticalAlignment: Text.AlignVCenter
|
|
}
|
|
}
|
|
Loader {
|
|
id: appIconLoader
|
|
active: root.image == "" && root.appIcon != ""
|
|
anchors.centerIn: parent
|
|
sourceComponent: IconImage {
|
|
id: appIconImage
|
|
implicitSize: root.appIconSize
|
|
asynchronous: true
|
|
source: Quickshell.iconPath(root.appIcon, "image-missing")
|
|
}
|
|
}
|
|
Loader {
|
|
id: notifImageLoader
|
|
active: root.image != ""
|
|
anchors.fill: parent
|
|
sourceComponent: Item {
|
|
anchors.fill: parent
|
|
StyledImage {
|
|
id: notifImage
|
|
anchors.fill: parent
|
|
readonly property int size: parent.width
|
|
|
|
source: root.image
|
|
fillMode: Image.PreserveAspectCrop
|
|
cache: false
|
|
antialiasing: true
|
|
asynchronous: true
|
|
|
|
layer.enabled: true
|
|
layer.effect: OpacityMask {
|
|
maskSource: Rectangle {
|
|
width: notifImage.size
|
|
height: notifImage.size
|
|
radius: Appearance.rounding.full
|
|
}
|
|
}
|
|
}
|
|
Loader {
|
|
id: notifImageAppIconLoader
|
|
active: root.appIcon != ""
|
|
anchors.bottom: parent.bottom
|
|
anchors.right: parent.right
|
|
sourceComponent: IconImage {
|
|
implicitSize: root.smallAppIconSize
|
|
asynchronous: true
|
|
source: Quickshell.iconPath(root.appIcon, "image-missing")
|
|
}
|
|
}
|
|
}
|
|
}
|
|
} |