8f42fc953d
This is a projection, not a development branch. The tree above was constructed from the internal source named below under a manifest that decides which paths may leave, then scanned as a whole tree rather than as a series of patches, and only then published. Public history starts here because the history before it was not admissible, and neither was the tree. What used to stand in this repository included a rescue copy of another machine, a directory of phone handoffs, deployment wired to one house, and a submodule pointing at a forge no stranger can reach. None of that was ever the product. It stays in the private forge, which is allowed to hold the whole working organism, and this is what was deliberately sent out instead. Three mechanisms produced this tree, in decreasing order of trust. A top-level path the manifest does not name never arrives at all, which is the one that catches directories nobody has thought of yet. Named internal files inside admitted roots are dropped. A short, reviewed table replaces deployment defaults that a public build must not carry -- an endpoint aimed at one LAN, a VPN profile belonging to one phone, packaging built from one checkout path. Everything after this commit is an ordinary publication with the same three trailers, so a force push stops being routine and starts meaning that something deliberate happened. The trailers bind the projection to its source without pretending the public SHA is the private one: same lineage, different tree, and the record says so. Source-Sha: 8f27b1e76a8fef560a336aba18e6990713ff1047 Policy-Sha: 6b261d2f3e6e1fb19874846ba4bb1dfe15565d25b8618c1c1afba0419c101d27 Tree-Digest: 18ec3563c5e5ef9a414993a9f6734b251ff9ed3cd56eebdd6cac01e45c6e3067
110 lines
3.1 KiB
QML
110 lines
3.1 KiB
QML
pragma ComponentBehavior: Bound
|
|
import Qt.labs.synchronizer
|
|
import QtQuick
|
|
import QtQuick.Layouts
|
|
import QtQuick.Controls
|
|
import Quickshell
|
|
import qs
|
|
import qs.services
|
|
import qs.modules.common
|
|
import qs.modules.common.widgets
|
|
import qs.modules.common.models.quickToggles
|
|
import qs.modules.common.functions
|
|
import qs.modules.waffle.looks
|
|
import qs.modules.waffle.actionCenter.toggles
|
|
|
|
Item {
|
|
id: root
|
|
|
|
property int columns: 3
|
|
property int rows: 2
|
|
property int currentPage: 0
|
|
readonly property int itemsPerPage: columns * rows
|
|
readonly property int pages: Math.ceil(toggles.length / itemsPerPage)
|
|
property list<string> toggles: Config.options.waffles.actionCenter.toggles
|
|
|
|
property real padding: 22
|
|
property real reducedBottomPadding: 12
|
|
implicitHeight: swipeView.implicitHeight + (padding - swipeView.padding) * 2 - reducedBottomPadding
|
|
|
|
function togglesInPage(index) {
|
|
var start = index * root.itemsPerPage;
|
|
var end = start + root.itemsPerPage;
|
|
return root.toggles.slice(start, end);
|
|
}
|
|
|
|
function decreasePage() {
|
|
if (root.currentPage > 0) {
|
|
root.currentPage -= 1;
|
|
}
|
|
}
|
|
|
|
function increasePage() {
|
|
if (root.currentPage < (root.pages - 1)) {
|
|
root.currentPage += 1;
|
|
}
|
|
}
|
|
|
|
clip: true
|
|
SwipeView {
|
|
id: swipeView
|
|
anchors {
|
|
fill: parent
|
|
topMargin: root.padding - swipeView.padding
|
|
bottomMargin: root.padding - swipeView.padding - root.reducedBottomPadding
|
|
}
|
|
padding: 4
|
|
leftPadding: root.padding
|
|
rightPadding: root.padding
|
|
spacing: padding
|
|
|
|
orientation: Qt.Vertical
|
|
clip: true
|
|
Synchronizer on currentIndex {
|
|
property alias source: root.currentPage
|
|
}
|
|
|
|
Repeater {
|
|
model: root.pages
|
|
delegate: GridLayout {
|
|
id: grid
|
|
required property int index
|
|
// width: SwipeView.view.width - root.padding * 2
|
|
// height: SwipeView.view.height - root.padding * 2
|
|
|
|
columns: root.columns
|
|
rows: root.rows
|
|
rowSpacing: 12
|
|
columnSpacing: 12
|
|
|
|
Repeater {
|
|
model: ScriptModel {
|
|
values: root.togglesInPage(grid.index)
|
|
}
|
|
delegate: ActionCenterTogglesDelegateChooser {}
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
VerticalPageIndicator {
|
|
anchors.verticalCenter: parent.verticalCenter
|
|
anchors.right: parent.right
|
|
anchors.rightMargin: 6
|
|
|
|
currentIndex: root.currentPage
|
|
count: root.pages
|
|
onClicked: (index) => root.currentPage = index
|
|
onIncreasePage: root.increasePage();
|
|
onDecreasePage: root.decreasePage();
|
|
}
|
|
|
|
FocusedScrollMouseArea {
|
|
z: 999
|
|
anchors.fill: parent
|
|
acceptedButtons: Qt.NoButton
|
|
hoverEnabled: false
|
|
onScrollUp: root.decreasePage();
|
|
onScrollDown: root.increasePage();
|
|
}
|
|
}
|