8f42fc953d
This is a projection, not a development branch. The tree above was constructed from the internal source named below under a manifest that decides which paths may leave, then scanned as a whole tree rather than as a series of patches, and only then published. Public history starts here because the history before it was not admissible, and neither was the tree. What used to stand in this repository included a rescue copy of another machine, a directory of phone handoffs, deployment wired to one house, and a submodule pointing at a forge no stranger can reach. None of that was ever the product. It stays in the private forge, which is allowed to hold the whole working organism, and this is what was deliberately sent out instead. Three mechanisms produced this tree, in decreasing order of trust. A top-level path the manifest does not name never arrives at all, which is the one that catches directories nobody has thought of yet. Named internal files inside admitted roots are dropped. A short, reviewed table replaces deployment defaults that a public build must not carry -- an endpoint aimed at one LAN, a VPN profile belonging to one phone, packaging built from one checkout path. Everything after this commit is an ordinary publication with the same three trailers, so a force push stops being routine and starts meaning that something deliberate happened. The trailers bind the projection to its source without pretending the public SHA is the private one: same lineage, different tree, and the record says so. Source-Sha: 8f27b1e76a8fef560a336aba18e6990713ff1047 Policy-Sha: 6b261d2f3e6e1fb19874846ba4bb1dfe15565d25b8618c1c1afba0419c101d27 Tree-Digest: 18ec3563c5e5ef9a414993a9f6734b251ff9ed3cd56eebdd6cac01e45c6e3067
124 lines
4.5 KiB
QML
124 lines
4.5 KiB
QML
pragma ComponentBehavior: Bound
|
|
import QtQuick
|
|
import QtQuick.Controls
|
|
import QtQuick.Layouts
|
|
import Quickshell
|
|
import Quickshell.Hyprland
|
|
import qs.services
|
|
import qs.modules.common
|
|
import qs.modules.common.functions
|
|
import qs.modules.waffle.looks
|
|
import qs.modules.waffle.bar
|
|
|
|
BarPopup {
|
|
id: root
|
|
|
|
closeOnFocusLost: false
|
|
onFocusCleared: {
|
|
const hasMenuOpen = contentItem.children.some(c => (c.menuOpen));
|
|
if (!hasMenuOpen)
|
|
root.close();
|
|
else
|
|
root.grabFocus();
|
|
}
|
|
|
|
contentItem: Item {
|
|
id: contentItem
|
|
anchors.centerIn: parent
|
|
implicitWidth: contentGrid.implicitWidth
|
|
implicitHeight: contentGrid.implicitHeight
|
|
GridLayout {
|
|
id: contentGrid
|
|
anchors.centerIn: parent
|
|
rows: Math.floor(Math.sqrt(TrayService.unpinnedItems.length))
|
|
columns: Math.ceil(TrayService.unpinnedItems.length / rows)
|
|
columnSpacing: 0
|
|
rowSpacing: 0
|
|
|
|
Repeater {
|
|
model: ScriptModel {
|
|
values: TrayService.unpinnedItems
|
|
onValuesChanged: {
|
|
root.updateAnchor();
|
|
if (values.length === 0) {
|
|
root.close();
|
|
}
|
|
}
|
|
}
|
|
delegate: TrayButton {
|
|
id: trayButton
|
|
required property var modelData
|
|
item: modelData
|
|
|
|
topInset: 0
|
|
bottomInset: 0
|
|
implicitWidth: 40
|
|
implicitHeight: 40
|
|
|
|
colBackground: ColorUtils.transparentize(Looks.colors.bg2)
|
|
colBackgroundHover: Looks.colors.bg2Hover
|
|
colBackgroundActive: Looks.colors.bg2Active
|
|
|
|
onMenuOpenChanged: {
|
|
// The overflow menu should only be closed when the user clicks outside
|
|
// However the focus grab refuses to reactivate, so we can't have that
|
|
// But most of the time the user dismisses the menu by clicking outside anyway,
|
|
// so this is acceptable.
|
|
if (!menuOpen) {
|
|
root.close();
|
|
}
|
|
}
|
|
|
|
property real initialX
|
|
property real initialY
|
|
|
|
Behavior on x {
|
|
animation: Looks.transition.move.createObject(this)
|
|
}
|
|
Behavior on y {
|
|
animation: Looks.transition.move.createObject(this)
|
|
}
|
|
|
|
MouseArea {
|
|
id: dragArea
|
|
anchors.fill: parent
|
|
drag.target: parent
|
|
drag.threshold: 2
|
|
|
|
onPressed: event => {
|
|
trayButton.Drag.hotSpot.x = event.x;
|
|
trayButton.Drag.hotSpot.y = event.y;
|
|
trayButton.initialX = trayButton.x;
|
|
trayButton.initialY = trayButton.y;
|
|
trayButton.Drag.active = true;
|
|
}
|
|
onReleased: {
|
|
if (!dragArea.drag.active) {
|
|
trayButton.click();
|
|
} else {
|
|
if (!unpinDropArea.containsDrag && unpinDropArea.willUnpin) {
|
|
// Quickshell would crash if we don't hide this item first. Took me fucking 3 hours to figure out...
|
|
trayButton.visible = false;
|
|
TrayService.togglePin(trayButton.item.id);
|
|
unpinDropArea.willUnpin = false;
|
|
} else {
|
|
trayButton.x = trayButton.initialX;
|
|
trayButton.y = trayButton.initialY;
|
|
}
|
|
}
|
|
trayButton.Drag.active = false;
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
DropArea {
|
|
id: unpinDropArea
|
|
anchors.fill: parent
|
|
property bool willUnpin: false
|
|
onEntered: willUnpin = false
|
|
onExited: willUnpin = true
|
|
}
|
|
}
|
|
}
|