8f42fc953d
This is a projection, not a development branch. The tree above was constructed from the internal source named below under a manifest that decides which paths may leave, then scanned as a whole tree rather than as a series of patches, and only then published. Public history starts here because the history before it was not admissible, and neither was the tree. What used to stand in this repository included a rescue copy of another machine, a directory of phone handoffs, deployment wired to one house, and a submodule pointing at a forge no stranger can reach. None of that was ever the product. It stays in the private forge, which is allowed to hold the whole working organism, and this is what was deliberately sent out instead. Three mechanisms produced this tree, in decreasing order of trust. A top-level path the manifest does not name never arrives at all, which is the one that catches directories nobody has thought of yet. Named internal files inside admitted roots are dropped. A short, reviewed table replaces deployment defaults that a public build must not carry -- an endpoint aimed at one LAN, a VPN profile belonging to one phone, packaging built from one checkout path. Everything after this commit is an ordinary publication with the same three trailers, so a force push stops being routine and starts meaning that something deliberate happened. The trailers bind the projection to its source without pretending the public SHA is the private one: same lineage, different tree, and the record says so. Source-Sha: 8f27b1e76a8fef560a336aba18e6990713ff1047 Policy-Sha: 6b261d2f3e6e1fb19874846ba4bb1dfe15565d25b8618c1c1afba0419c101d27 Tree-Digest: 18ec3563c5e5ef9a414993a9f6734b251ff9ed3cd56eebdd6cac01e45c6e3067
78 lines
1.8 KiB
QML
78 lines
1.8 KiB
QML
//@ pragma UseQApplication
|
|
//@ pragma Env QS_NO_RELOAD_POPUP=1
|
|
//@ pragma Env QT_QUICK_CONTROLS_STYLE=Basic
|
|
//@ pragma Env QT_QUICK_FLICKABLE_WHEEL_DECELERATION=10000
|
|
|
|
// Remove two slashes below and adjust the value to change the UI scale
|
|
////@ pragma Env QT_SCALE_FACTOR=1
|
|
|
|
import "modules/common"
|
|
import "services"
|
|
import "panelFamilies"
|
|
|
|
import QtQuick
|
|
import QtQuick.Window
|
|
import Quickshell
|
|
import Quickshell.Io
|
|
import Quickshell.Hyprland
|
|
|
|
ShellRoot {
|
|
id: root
|
|
|
|
// Stuff for every panel family
|
|
ReloadPopup {}
|
|
DeviceConnectNotification {}
|
|
|
|
Component.onCompleted: {
|
|
MaterialThemeLoader.reapplyTheme()
|
|
Hyprsunset.load()
|
|
FirstRunExperience.load()
|
|
ConflictKiller.load()
|
|
Cliphist.refresh()
|
|
Wallpapers.load()
|
|
Updates.load()
|
|
}
|
|
|
|
|
|
// Panel families
|
|
property list<string> families: ["ii", "waffle"]
|
|
function cyclePanelFamily() {
|
|
const currentIndex = families.indexOf(Config.options.panelFamily)
|
|
const nextIndex = (currentIndex + 1) % families.length
|
|
Config.options.panelFamily = families[nextIndex]
|
|
}
|
|
|
|
component PanelFamilyLoader: LazyLoader {
|
|
required property string identifier
|
|
property bool extraCondition: true
|
|
active: Config.ready && Config.options.panelFamily === identifier && extraCondition
|
|
}
|
|
|
|
PanelFamilyLoader {
|
|
identifier: "ii"
|
|
component: IllogicalImpulseFamily {}
|
|
}
|
|
|
|
PanelFamilyLoader {
|
|
identifier: "waffle"
|
|
component: WaffleFamily {}
|
|
}
|
|
|
|
|
|
// Shortcuts
|
|
IpcHandler {
|
|
target: "panelFamily"
|
|
|
|
function cycle(): void {
|
|
root.cyclePanelFamily()
|
|
}
|
|
}
|
|
|
|
GlobalShortcut {
|
|
name: "panelFamilyCycle"
|
|
description: "Cycles panel family"
|
|
|
|
onPressed: root.cyclePanelFamily()
|
|
}
|
|
}
|
|
|