8f42fc953d
This is a projection, not a development branch. The tree above was constructed from the internal source named below under a manifest that decides which paths may leave, then scanned as a whole tree rather than as a series of patches, and only then published. Public history starts here because the history before it was not admissible, and neither was the tree. What used to stand in this repository included a rescue copy of another machine, a directory of phone handoffs, deployment wired to one house, and a submodule pointing at a forge no stranger can reach. None of that was ever the product. It stays in the private forge, which is allowed to hold the whole working organism, and this is what was deliberately sent out instead. Three mechanisms produced this tree, in decreasing order of trust. A top-level path the manifest does not name never arrives at all, which is the one that catches directories nobody has thought of yet. Named internal files inside admitted roots are dropped. A short, reviewed table replaces deployment defaults that a public build must not carry -- an endpoint aimed at one LAN, a VPN profile belonging to one phone, packaging built from one checkout path. Everything after this commit is an ordinary publication with the same three trailers, so a force push stops being routine and starts meaning that something deliberate happened. The trailers bind the projection to its source without pretending the public SHA is the private one: same lineage, different tree, and the record says so. Source-Sha: 8f27b1e76a8fef560a336aba18e6990713ff1047 Policy-Sha: 6b261d2f3e6e1fb19874846ba4bb1dfe15565d25b8618c1c1afba0419c101d27 Tree-Digest: 18ec3563c5e5ef9a414993a9f6734b251ff9ed3cd56eebdd6cac01e45c6e3067
50 lines
1.7 KiB
QML
50 lines
1.7 KiB
QML
// Haptic feedback, through feedbackd.
|
|
//
|
|
// Not a direct write to /dev/input/eventN. feedbackd already owns the force
|
|
// feedback device (it claimed event4 at boot the moment the kernel exposed
|
|
// pmi8998_haptics), it already arbitrates between callers, and it already
|
|
// carries the user's profile — full / quiet / silent — which is where "do not
|
|
// buzz right now" is supposed to be decided. A second writer to the same
|
|
// device would be the competing-writer mistake again, in a new subsystem.
|
|
//
|
|
// The event names are feedbackd's own vocabulary, so the theme decides what
|
|
// each one feels like. `button-pressed` maps to VibraPattern in the `quiet`
|
|
// profile, which is the same event squeekboard fires per key.
|
|
pragma Singleton
|
|
|
|
import QtQuick
|
|
import Quickshell
|
|
import Quickshell.Io
|
|
|
|
Singleton {
|
|
id: root
|
|
|
|
// Off switch that does not depend on reaching feedbackd to honour it.
|
|
property bool enabled: true
|
|
|
|
function trigger(event) {
|
|
if (!root.enabled)
|
|
return;
|
|
Quickshell.execDetached(["busctl", "call", "--user",
|
|
"org.sigxcpu.Feedback", "/org/sigxcpu/Feedback",
|
|
"org.sigxcpu.Feedback", "TriggerFeedback",
|
|
"ssa{sv}i", "souveraine", event, "0", "-1"]);
|
|
}
|
|
|
|
// A detent. Short and light: this fires once per entry the thumb crosses
|
|
// on the dial, so anything longer would smear into the next one.
|
|
function tick() {
|
|
root.trigger("button-pressed");
|
|
}
|
|
|
|
// Something completed.
|
|
function confirm() {
|
|
root.trigger("button-released");
|
|
}
|
|
|
|
// Something was refused. Distinct on purpose — a refusal that feels like a
|
|
// success is worse than no feedback at all.
|
|
function refuse() {
|
|
root.trigger("bell-terminal");
|
|
}
|
|
}
|