e31c3aaf62
Grows Souveraine's own surfaces on top of the borrowed ii shell and drops the separate pill shell in favor of one integrated navigation rail. Session arbiter (functions/Session.qml): probe logind's Can* methods over busctl instead of guessing from installed binaries -- the answer carries the polkit tier (yes/challenge/na), so a swapless phone reports hibernate as na and refuses honestly rather than firing a verb that no-ops. Verbs run through a Process that logs exit codes and tracks lastAction; refusals log too. The busctl output is parsed with awk, not a sed regex buried under four escaping layers -- the sed version returned nothing on the phone and left every capability stuck at "unknown" (invisible on the laptop, where timing masked it). Every structured result is JSON-over-string; quickshell maps a var return to void. Lock trust: screenLocked (the shell's lock request) is now distinct from screenLockSecure (WlSessionLock.secure, the compositor's acknowledgement, mirrored from LockScreen). Cards that disclose personal data gate on secure, not on a button press. LockContentPolicy centralizes the ambient/personal/ step-up tiers so no card grows its own private rule. New first-party namespace modules/souveraine/: LockMediaCard, LockSurfaceHost, SystemGestureRail -- owned surfaces, not ii patches. IdleCoordinator gives one staged idle vocabulary (dim/lock) gated behind nativeCoordinatorEnabled, off until the native Wayland idle-notify is verified on the Pixel compositor; hypridle stays the adapter. WallpaperAssets selects aspect-aware variants for phone-vs-laptop display shapes. Pill retired: pill/shell.qml and PillConfig gone, replaced by NavigationConfig and the gesture rail. Hyprland starts qs -c souveraine directly; no secondary shell, no qsConfig flip. Verified on the phone: session.* reports challenge/na correctly, hibernate and unlock refuse, inhibit round-trips with its reason.
338 lines
12 KiB
QML
338 lines
12 KiB
QML
import qs
|
|
import qs.services
|
|
import qs.modules.common
|
|
import qs.modules.common.widgets
|
|
import qs.modules.common.functions
|
|
import QtQuick
|
|
import QtQuick.Controls
|
|
import QtQuick.Layouts
|
|
import Quickshell
|
|
import Quickshell.Io
|
|
import Quickshell.Wayland
|
|
import Quickshell.Hyprland
|
|
|
|
Scope {
|
|
id: root
|
|
property var focusedScreen: Quickshell.screens.find(s => s.name === Hyprland.focusedMonitor?.name)
|
|
|
|
Loader {
|
|
id: sessionLoader
|
|
active: GlobalStates.sessionOpen
|
|
onActiveChanged: {
|
|
if (sessionLoader.active)
|
|
SessionWarnings.refresh();
|
|
}
|
|
|
|
Connections {
|
|
target: GlobalStates
|
|
function onScreenLockedChanged() {
|
|
if (GlobalStates.screenLocked) {
|
|
GlobalStates.sessionOpen = false;
|
|
}
|
|
}
|
|
}
|
|
|
|
sourceComponent: PanelWindow { // Session menu
|
|
id: sessionRoot
|
|
visible: sessionLoader.active
|
|
property string subtitle
|
|
|
|
function hide() {
|
|
GlobalStates.sessionOpen = false;
|
|
}
|
|
|
|
exclusionMode: ExclusionMode.Ignore
|
|
WlrLayershell.namespace: "quickshell:session"
|
|
WlrLayershell.layer: WlrLayer.Overlay
|
|
WlrLayershell.keyboardFocus: WlrKeyboardFocus.Exclusive
|
|
color: ColorUtils.transparentize(Appearance.m3colors.m3background, Appearance.m3colors.darkmode ? 0.05 : 0.12)
|
|
|
|
anchors {
|
|
top: true
|
|
left: true
|
|
right: true
|
|
}
|
|
|
|
implicitWidth: root.focusedScreen?.width ?? 0
|
|
implicitHeight: root.focusedScreen?.height ?? 0
|
|
|
|
MouseArea {
|
|
id: sessionMouseArea
|
|
anchors.fill: parent
|
|
onClicked: {
|
|
sessionRoot.hide();
|
|
}
|
|
}
|
|
|
|
ColumnLayout { // Content column
|
|
id: contentColumn
|
|
anchors.centerIn: parent
|
|
spacing: 15
|
|
|
|
Keys.onPressed: event => {
|
|
if (event.key === Qt.Key_Escape) {
|
|
sessionRoot.hide();
|
|
}
|
|
}
|
|
|
|
ColumnLayout {
|
|
Layout.alignment: Qt.AlignHCenter
|
|
spacing: 0
|
|
StyledText {
|
|
// Title
|
|
Layout.alignment: Qt.AlignHCenter
|
|
horizontalAlignment: Text.AlignHCenter
|
|
font {
|
|
family: Appearance.font.family.title
|
|
pixelSize: Appearance.font.pixelSize.title
|
|
variableAxes: Appearance.font.variableAxes.title
|
|
}
|
|
text: Translation.tr("Session")
|
|
}
|
|
|
|
StyledText {
|
|
// Small instruction
|
|
Layout.alignment: Qt.AlignHCenter
|
|
horizontalAlignment: Text.AlignHCenter
|
|
font.pixelSize: Appearance.font.pixelSize.normal
|
|
text: Translation.tr("Arrow keys to navigate, Enter to select\nEsc or click anywhere to cancel")
|
|
}
|
|
}
|
|
|
|
GridLayout {
|
|
columns: 4
|
|
columnSpacing: 15
|
|
rowSpacing: 15
|
|
|
|
SessionActionButton {
|
|
id: sessionLock
|
|
focus: sessionRoot.visible
|
|
buttonIcon: "lock"
|
|
buttonText: Translation.tr("Lock")
|
|
onClicked: {
|
|
Session.lock();
|
|
sessionRoot.hide();
|
|
}
|
|
onFocusChanged: {
|
|
if (focus)
|
|
sessionRoot.subtitle = buttonText;
|
|
}
|
|
KeyNavigation.right: sessionSleep
|
|
KeyNavigation.down: sessionHibernate
|
|
}
|
|
SessionActionButton {
|
|
id: sessionSleep
|
|
buttonIcon: "dark_mode"
|
|
buttonText: Translation.tr("Sleep")
|
|
onClicked: {
|
|
Session.suspend();
|
|
sessionRoot.hide();
|
|
}
|
|
onFocusChanged: {
|
|
if (focus)
|
|
sessionRoot.subtitle = buttonText;
|
|
}
|
|
KeyNavigation.left: sessionLock
|
|
KeyNavigation.right: sessionLogout
|
|
KeyNavigation.down: sessionShutdown
|
|
}
|
|
SessionActionButton {
|
|
id: sessionLogout
|
|
buttonIcon: "logout"
|
|
buttonText: Translation.tr("Logout")
|
|
onClicked: {
|
|
Session.logout();
|
|
sessionRoot.hide();
|
|
}
|
|
onFocusChanged: {
|
|
if (focus)
|
|
sessionRoot.subtitle = buttonText;
|
|
}
|
|
KeyNavigation.left: sessionSleep
|
|
KeyNavigation.right: sessionTaskManager
|
|
KeyNavigation.down: sessionReboot
|
|
}
|
|
SessionActionButton {
|
|
id: sessionTaskManager
|
|
buttonIcon: "browse_activity"
|
|
buttonText: Translation.tr("Task Manager")
|
|
onClicked: {
|
|
Session.launchTaskManager();
|
|
sessionRoot.hide();
|
|
}
|
|
onFocusChanged: {
|
|
if (focus)
|
|
sessionRoot.subtitle = buttonText;
|
|
}
|
|
KeyNavigation.left: sessionLogout
|
|
KeyNavigation.down: sessionFirmwareReboot
|
|
}
|
|
|
|
SessionActionButton {
|
|
id: sessionHibernate
|
|
buttonIcon: "downloading"
|
|
buttonText: Translation.tr("Hibernate")
|
|
onClicked: {
|
|
Session.hibernate();
|
|
sessionRoot.hide();
|
|
}
|
|
onFocusChanged: {
|
|
if (focus)
|
|
sessionRoot.subtitle = buttonText;
|
|
}
|
|
KeyNavigation.up: sessionLock
|
|
KeyNavigation.right: sessionShutdown
|
|
}
|
|
SessionActionButton {
|
|
id: sessionShutdown
|
|
buttonIcon: "power_settings_new"
|
|
buttonText: Translation.tr("Shutdown")
|
|
onClicked: {
|
|
Session.poweroff();
|
|
sessionRoot.hide();
|
|
}
|
|
onFocusChanged: {
|
|
if (focus)
|
|
sessionRoot.subtitle = buttonText;
|
|
}
|
|
KeyNavigation.left: sessionHibernate
|
|
KeyNavigation.right: sessionReboot
|
|
KeyNavigation.up: sessionSleep
|
|
}
|
|
SessionActionButton {
|
|
id: sessionReboot
|
|
buttonIcon: "restart_alt"
|
|
buttonText: Translation.tr("Reboot")
|
|
onClicked: {
|
|
Session.reboot();
|
|
sessionRoot.hide();
|
|
}
|
|
onFocusChanged: {
|
|
if (focus)
|
|
sessionRoot.subtitle = buttonText;
|
|
}
|
|
KeyNavigation.left: sessionShutdown
|
|
KeyNavigation.right: sessionFirmwareReboot
|
|
KeyNavigation.up: sessionLogout
|
|
}
|
|
SessionActionButton {
|
|
id: sessionFirmwareReboot
|
|
buttonIcon: "settings_applications"
|
|
buttonText: Translation.tr("Reboot to firmware settings")
|
|
onClicked: {
|
|
Session.rebootToFirmware();
|
|
sessionRoot.hide();
|
|
}
|
|
onFocusChanged: {
|
|
if (focus)
|
|
sessionRoot.subtitle = buttonText;
|
|
}
|
|
KeyNavigation.up: sessionTaskManager
|
|
KeyNavigation.left: sessionReboot
|
|
}
|
|
}
|
|
|
|
DescriptionLabel {
|
|
Layout.alignment: Qt.AlignHCenter
|
|
text: sessionRoot.subtitle
|
|
}
|
|
}
|
|
|
|
ColumnLayout {
|
|
anchors {
|
|
top: contentColumn.bottom
|
|
topMargin: 10
|
|
horizontalCenter: contentColumn.horizontalCenter
|
|
}
|
|
spacing: 10
|
|
|
|
Loader {
|
|
Layout.alignment: Qt.AlignHCenter
|
|
active: SessionWarnings.downloadRunning
|
|
visible: active
|
|
sourceComponent: DescriptionLabel {
|
|
text: Translation.tr("There might be a download in progress. Check your Downloads folder.")
|
|
textColor: Appearance.m3colors.m3onErrorContainer
|
|
color: Appearance.m3colors.m3errorContainer
|
|
}
|
|
}
|
|
|
|
Loader {
|
|
Layout.alignment: Qt.AlignHCenter
|
|
active: SessionWarnings.packageManagerRunning
|
|
visible: active
|
|
sourceComponent: DescriptionLabel {
|
|
text: Translation.tr("Your package manager is running")
|
|
textColor: Appearance.m3colors.m3onErrorContainer
|
|
color: Appearance.m3colors.m3errorContainer
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
component DescriptionLabel: Rectangle {
|
|
id: descriptionLabel
|
|
property string text
|
|
property color textColor: Appearance.colors.colOnTooltip
|
|
color: Appearance.colors.colTooltip
|
|
clip: true
|
|
radius: Appearance.rounding.normal
|
|
implicitHeight: descriptionLabelText.implicitHeight + 10 * 2
|
|
implicitWidth: descriptionLabelText.implicitWidth + 15 * 2
|
|
|
|
Behavior on implicitWidth {
|
|
animation: Appearance.animation.elementMove.numberAnimation.createObject(this)
|
|
}
|
|
|
|
StyledText {
|
|
id: descriptionLabelText
|
|
anchors.centerIn: parent
|
|
color: descriptionLabel.textColor
|
|
text: descriptionLabel.text
|
|
}
|
|
}
|
|
|
|
IpcHandler {
|
|
target: "sessionMenu"
|
|
|
|
function toggle(): void {
|
|
GlobalStates.sessionOpen = !GlobalStates.sessionOpen;
|
|
}
|
|
|
|
function close(): void {
|
|
GlobalStates.sessionOpen = false;
|
|
}
|
|
|
|
function open(): void {
|
|
GlobalStates.sessionOpen = true;
|
|
}
|
|
}
|
|
|
|
GlobalShortcut {
|
|
name: "sessionToggle"
|
|
description: "Toggles session screen on press"
|
|
|
|
onPressed: {
|
|
GlobalStates.sessionOpen = !GlobalStates.sessionOpen;
|
|
}
|
|
}
|
|
|
|
GlobalShortcut {
|
|
name: "sessionOpen"
|
|
description: "Opens session screen on press"
|
|
|
|
onPressed: {
|
|
GlobalStates.sessionOpen = true;
|
|
}
|
|
}
|
|
|
|
GlobalShortcut {
|
|
name: "sessionClose"
|
|
description: "Closes session screen on press"
|
|
|
|
onPressed: {
|
|
GlobalStates.sessionOpen = false;
|
|
}
|
|
}
|
|
}
|